搜索后未找到访问表单记录源

Question

我开发了一个拆分表单，它使用以下记录源：

SELECT * FROM [CCG Complaints];

表单效果很好，我对这方面没有任何问题。

用户有两个按钮：一个用于搜索，一个用于显示所有记录。

当我在执行搜索后关闭表单然后再次重新打开它（在表单视图中）时会出现问题：

但是，每当我在关闭表单之前单击Show all 时，它都会在表单视图中成功打开，并且没有错误。

另一个特点是，收到上述错误后，我可以在设计视图中打开表单，然后可以在表单视图中查看它而不会出现错误消息 - 只有在表单中打开表单时才会出现错误第一时间查看。

为什么会这样，我可以做些什么来纠正它？

我用于按钮的代码在这里：

Private Sub search_Click()
Dim strSearch As String
Dim strText As String
    If Len(Me.txtSearch.Value & vbNullString) = 0 Then
        MsgBox ("Enter a search term.")
    Else
        strText = Me.txtSearch.Value
        strSearch = "SELECT* from [CCG Complaints] where [Ref no] Like ""*" & strText & "*"" or [lastName] Like ""*" & strText & "*"" Or CCG Like ""*" & strText & "*"" "
        Me.RecordSource = strSearch
    End If
End Sub

Private Sub showAll_Click()
    Dim strSearch As String
    strSearch = "SELECT * from [CCG Complaints]"
    Me.RecordSource = strSearch
End Sub

Answer 1

不要更改记录源，而是对现有记录应用过滤器。

Me.filter =  "[Ref no] Like  ""*" & strText & "*"" or [lastName] Like ""*" & strText & "*"" Or CCG Like ""*" & strText & "*"" "
Me.FilterOn = True

然后重置

Me.Filter = ""
Me.FilterOn = False

请注意，如果您的记录集变得稍微大一点，这种通配符搜索大量字段将变得非常低效。您可能想查看更强大的搜索方法。这个http://allenbrowne.com/ser-62.html 是一个更完整的解决方案。

Answer 2

我建议将 RecordSource 设置为[CCG Complaints]，而不是更改它。

改为使用.Filter 属性，这是实现表单过滤器的常用方法：

Private Sub search_Click()
Dim strSearch As String
Dim strText As String
    If Len(Me.txtSearch.Value & vbNullString) = 0 Then
        MsgBox ("Enter a search term.")
    Else
        strText = Me.txtSearch.Value
        strSearch = "[Ref no] Like ""*" & strText & "*"" or [lastName] Like ""*" & strText & "*"" Or CCG Like ""*" & strText & "*"" "
        Me.Filter = strSearch
        Me.FilterOn = True
    End If
End Sub

Private Sub showAll_Click()
    Me.Filter = ""
    Me.FilterOn = False
End Sub