尝试使用基于子表单控件的 DoCmd.OpenForm 打开表单

Question

我有一个带有未绑定控件 (Text0) 的未绑定表单。在 Text0 中，我输入一个 RefNo。我想打开另一个表单 (frmDisclosure)，它有一个包含 RefNo 的子表单 (frmRefNosList)。我打开 frmDisclosure 的代码是： 私有子 Command8_Click()

Dim Refce As Variant

DoCmd.OpenForm "frmDisclosure"
Forms!frmDisclosure.FilterOn = False
Refce = "Forms!frmDisclosure!frmRefNosList.Form!RefNo"
DoCmd.OpenForm "frmDisclosure", acNormal, "", Refce & " = " & Me.Text0, , acNormal

End Sub

Answer 1

在我们在聊天中讨论之后，我模拟了一些希望看起来像你想要做的事情：

Link to Access file mock-up.

对于稍后可能会阅读本文的其他人，这里有一些说明：

• 表单 Form1 上有一个名为 Text0 的文本框和一个按钮。
• 按下按钮时应该打开 Form2 子窗体就可以了。
• Form2 然后应该打开到某个记录，然后过滤 子窗体上显示的记录全部使用 Text0 中提供的值

这是我的 Form1 模型的样子：

所以当我提供 RefNo 并单击按钮时...

...在该按钮的单击事件上运行以下代码（带注释）：

Private Sub cmdOpen_Click()

    ' check user has provided a RefNo in the textbox...
    If _
        Me.Text0 = "" Or _
        IsNull(Me.Text0) _
    Then

        ' ...if a RefNo has not been provided, give an error message
        MsgBox "Please provide a Ref No.", vbExclamation Or vbOKOnly, "Disclosure Search"

    Else

        ' ...if a RefNo has been provided, look in the table that lists an applicant's
        ' forms and return the ApplicantID (or equivalent field you're using) for the RefNo provided
        Dim varApplicantID As Variant
        varApplicantID = DLookup("ApplicantID", "tblRefNos", "RefNo=" & Me.Text0)

        ' ...check that an applicant record can be actually be found from the RefNo provided
        If _
            IsNull(varApplicantID) _
        Then

            '... if an applicant record is not found, give an error message
            MsgBox "Could not find an applicant with the RefNo provided.", vbExclamation Or vbOKOnly, "Disclosure Search"

        Else

            '... if an applicant record is found, open Form2 to that applicant's record
            DoCmd.OpenForm "Form2", , , "ApplicantID=" & varApplicantID

            '... and then filter the subform on Form2 by the RefNo provided
            Forms!Form2!frmApplicantForms_sub.Form.Filter = "RefNo=" & Me.Text0
            Forms!Form2!frmApplicantForms_sub.Form.FilterOn = True
            Forms!Form2!frmApplicantForms_sub.Form.Requery

        End If

    End If

End Sub

这将导致 Form2 打开从提供的 RefNo 派生的正确申请人记录，并通过提供的 RefNo 过滤子表单：

您的确切项目布局可能与我所模拟的有所不同，因此可能需要针对您的设置进行一些调整，但希望我在这里说明的原则能够很容易翻译。

祝你好运！

Answer 2

这不是我想要的答案，而是：我创建了一个查询，该查询产生了对应于未绑定表单上 Text0 的 frmDisclosure 的 ID 号。然后，我使用 DLookup 从未绑定的表单中检索该 ID 号，并以这种方式打开 frmDisclosure。在未绑定的表单中完成所有操作会更好。