一个单元格中带有（多个数组 - 多个表）的 FILTER 函数 - Excel

Question

我有两个不同的表格（Table1 和 Table2 在两个不同的 Excel 工作表中。（可能有两个以上的表格，例如 3 或 4）

第三张表用于报告/过滤。现在在第三张/报告表中，我想在一个单元格中使用过滤器功能，并希望根据给定的两个表的包含标准将两个表中的两个表溢出

即

=FILTER(Table1 + Table2
OR
=SORT(FILTER(Table1,inclue,"")+FILTER(Table2,Inclue,"")) << it adds the two results if numbers

我希望我解释清楚 我正在尝试一次过滤显示结果的两个（所有）表，而我要做的只是使用公式栏，而不是 VBA。请帮我这样做

Answer 1

您可以使用LET一次在每个表中进行计算。

例如：

=LET(x, Table1,
y, Table2,
x1, SUM(FILTER(x, range_table1=value)),
y1, SUM(FILTER(y, range_table2=value)),
x1+y1)

按照@Scott Craner 的建议进行编辑：如果您想将数据叠加在一起，您可以使用SEQUENCE。编辑@chris neilsen here 建议的一个很好的改进显示了一种比我最初通过对一系列行和列进行索引的方式更简洁的方法。

=LET(x, table1, y, table2,
rows1, ROWS(x), rows2, ROWS(y),
myrows, SEQUENCE(rows1+rows2),
mycols, SEQUENCE(1,COLUMNS(x)),
IF(myrows<=rows1, x, INDEX(y, myrows-rows1, mycols)))

Answer 2

两个表的“并集”可以实现为

=LET(x, table1, y, table2,
rows1, ROWS(x), rows2, ROWS(y),
myrows, SEQUENCE(rows1+rows2),
mycols, SEQUENCE(1,COLUMNS(x)),
IF(myrows<=rows1, x, INDEX(y, myrows-rows1, mycols)))

3张表可以扩展为

=LET(x, Table1, y, Table2, z, Table3,
rows1, ROWS(x), rows2, ROWS(y), rows3, ROWS(z),
myrows, SEQUENCE(rows1+rows2+rows3),
mycols, SEQUENCE(1,COLUMNS(x)),
IF(myrows<=rows1, x, 
IF(myrows<=(rows1+rows2),INDEX(y, myrows-rows1, mycols), 
INDEX(z, myrows-rows1-rows2, mycols))))

对于三个以上的表，遵循相同的模式