T-SQL为什么除以零不会在order by子句中产生错误

Question

我在一个程序中发现了一些我最初认为不正确的语句，但经过测试后，我确信它们运行良好。我无法理解的是方式。

我有一个简单的表，其中包含记录 id、pts 和 ptsOf 列：

DECLARE @DataSource TABLE
(
     RecordID TINYINT
    ,Pts   INT
    ,PtsOf INT
)

INSERT INTO @DataSource
VALUES (1,5,5)
      ,(1,7,8)
      ,(1,3,5)
      ,(2,5,0)

我需要的是使用以下公式计算每条记录的总分：

SUM(pts)/SUM(ptsOf) * 100

因此，上面的语句将产生以下错误，因为对于最后一条记录，我将有 5/0：

消息 8134，级别 16，状态 1，行 21 遇到除以零错误。

但我发现的语句仅在 select 子句中检查除以零，而在 order by 子句中没有：

 SELECT  RecordID
         ,CAST(CAST(SUM(Pts) AS decimal) / CASE SUM(PtsOf) WHEN 0 THEN NULL ELSE SUM(PtsOf) END * 100 AS decimal(18, 0))
 FROM @DataSource
 GROUP BY RecordID
 ORDER BY RecordID,  CAST(CAST(SUM(Pts) AS decimal) / SUM(PtsOf) * 100 AS decimal(18, 0)) ASC

为什么order by类中的计算没有产生错误？

以下是完整示例：

SET NOCOUNT ON
GO

    DECLARE @DataSource TABLE
    (
         RecordID TINYINT
        ,Pts   INT
        ,PtsOf INT
    )

    INSERT INTO @DataSource
    VALUES (1,5,5)
          ,(1,7,8)
          ,(1,3,5)
          ,(2,5,0)

     SELECT  RecordID
             ,CAST(CAST(SUM(Pts) AS decimal) / CASE SUM(PtsOf) WHEN 0 THEN NULL ELSE SUM(PtsOf) END * 100 AS decimal(18, 0))
     FROM @DataSource
     GROUP BY RecordID
     ORDER BY RecordID,  CAST(CAST(SUM(Pts) AS decimal) / SUM(PtsOf) * 100 AS decimal(18, 0)) ASC

SET NOCOUNT OFF
GO

Answer 1

我相信ORDER BY 中的第二个子句在这种特殊情况下会被忽略。毕竟，如果你这样做：

DECLARE @t TABLE(i INT PRIMARY KEY, x UNIQUEIDENTIFIER);

INSERT @t VALUES(1,NEWID()),(2,NEWID()),(3,NEWID()),(4,NEWID());

SELECT i, x FROM @t ORDER BY i, x;

x 不在ORDER BY 中考虑，为什么会这样呢？ ORDER BY 子句中的第一个实体已经规定了顺序，第二个子句不能更改它。由于您按RecordID 进行分组，SQL Server 足够聪明地意识到ORDER BY 中的第一个元素是唯一的，因此不需要考虑第二个元素。我无法证明这一点，当第二个元素实际上对 SQL Server 更清楚时，我可以通过使用常量使其失败，例如：

ORDER BY RecordID, CONVERT(1/0);

但是当 SQL Server 不容易知道列的输出，并且无论如何它不能对输出做任何有用的事情时，它会做正确的事情（恕我直言）并丢弃表达式而不完全评估它并导致运行时错误。如果您不首先按保证唯一的列排序，也可以返回错误：

ORDER BY CAST(CAST(SUM(Pts) AS decimal) / SUM(PtsOf) * 100 AS decimal(18, 0));