拆分分隔符分隔的字符串并插入到oracle 11中的表中

Question

我有分隔符分隔的输入字符串，它可以有大约 40 个标记（数量可能会增加），我想使用 oracle 11 中的存储过程将这些值插入到表中； 最好的方法是什么

1. 创建一个包含 40 个 IN 参数的 SP 并使用它来插入。
2. 创建一个带有 1 个 IN 参数的 SP，它将采用该字符串并拆分分隔符分隔的标记并将它们插入到表中

如果第二种方法看起来不错，那么请建议如何实现它？？

例如，如果一个字符串类似于"abc,123,xyz,pqr,12"（这里的分隔符是逗号） 所以在运行 SP 我的表 table1(A varchar2, B Number, C varchar2, D varchar2, E number ) 应该有类似的条目

A  | B | C | D | E
abc|123|xys|pqr |12

我想出了以下解决方案，不确定性能，有没有更好的方法来做同样的事情？

declare
  string_to_parse varchar2(2000) := 'abc,123,xyz,pqr,12';
  A varchar2(4);
  B number;
  C varchar2(4);
  D varchar2(4);
  E number;
begin

  string_to_parse := string_to_parse||',';

   A  := REGEXP_SUBSTR(string_to_parse,'[^,]+', 1, 1);
   B  := TO_NUMBER(REGEXP_SUBSTR(string_to_parse,'[^,]+', 1, 2));
   C  := REGEXP_SUBSTR(string_to_parse,'[^,]+', 1, 3);
   D  := REGEXP_SUBSTR(string_to_parse,'[^,]+', 1, 4);
   E  := TO_NUMBER(REGEXP_SUBSTR(string_to_parse,'[^,]+', 1, 5));
   dbms_output.put_line('A ' || A || ' B ' || B || ' c ' || c || ' D ' || D || ' E ' || E);
--insert into table
end;

Answer 1

在这种特殊情况下，分裂离目标还有很长的路要走。 考虑到一个目标表可能有很多列（是的，5 个列在一个不同的变量中处理每个列都太多了），我建议使用模式字典来增加一些灵活性。

让我们看一个带有两个参数的过程：一个表名和一个包含逗号分隔值列表的字符串。 这里假设该表只有字符串、数字和时间列。要实现完整版本，请在程序开始时添加对所有必需数据类型的处理。

注意，在中间我们使用标准 SQL 方法将一个字符串拆分为一个子字符串表：

select level as column_id, 
       REGEXP_SUBSTR(pi_values_list, '[^,]+', 1, level) as column_val 
  from dual connect by REGEXP_SUBSTR(pi_values_list, '[^,]+', 1, level) is not null;

这是整个过程：

  create or replace procedure myInsertInto(pi_table_name  char,
                                           pi_values_list char)
  is
    v_statement     varchar2(30000) := 'INSERT INTO %TABLE_NAME% (%COLUMNS_LIST%) VALUES (%VALUES_LIST%)';
    v_columns_list  varchar2(10000);
    v_values_list   varchar2(10000);
  begin

    SELECT LISTAGG(T.column_name, ',') within group (order by T.column_id) ,
           LISTAGG( -- implement specific types handling here
                    CASE
                    WHEN S.column_val IS NULL
                      THEN 'NULL'
                    WHEN T.data_type = 'NUMBER'
                      THEN S.column_val
                    WHEN T.data_type IN ('DATE', 'TIMESTAMP') 
                      THEN 'TIMESTAMP ''' || S.column_val || ''''
                    WHEN T.data_type like '%CHAR%' 
                      THEN '''' || S.column_val || ''''                    
                    ELSE 'NULL'
                    END, 
           ',') within group (order by T.column_id)
    into v_columns_list,
         v_values_list
    from user_tab_cols T,
         (select level as column_id, REGEXP_SUBSTR(pi_values_list, '[^,]+', 1, level) as column_val 
            from dual connect by REGEXP_SUBSTR(pi_values_list, '[^,]+', 1, level) is not null) S
   where T.table_name = pi_table_name
     and T.column_id = S.column_id;

    if v_columns_list IS NULL then
      raise_application_error(-20000, 'Not found columns for table ' || pi_table_name);
    end if;

    -- finalizing the statement
    v_statement := replace(v_statement, '%TABLE_NAME%', pi_table_name);      
    v_statement := replace(v_statement, '%COLUMNS_LIST%', v_columns_list);      
    v_statement := replace(v_statement, '%VALUES_LIST%', v_values_list);

    execute immediate v_statement;
  end;
  /

那就这样用吧

create table MY_TABLE (
  col_a VARCHAR2(10),
  col_b NUMBER,
  col_c VARCHAR2(10),
  col_d DATE,
  col_E VARCHAR2(10) default 'DEFAULT'
);



begin
  myInsertInto('MY_TABLE', 'abc,123,xyz,2018-01-02 23:01:10,pqr' );
  myInsertInto('MY_TABLE', 'def,345,mkr' );
  myInsertInto('MY_TABLE', 'fgh' );
end;
/

Answer 2

第一种方法是禁止的。

第二个可能有效。 简单地说：

1. 将输入字符串分配给变量 s。

现在，循环中：

1. 如果 s 的长度为 0，则退出循环
2. 使用 instr 查找第一次出现的分隔符 (',')。将其分配给 X
3. 如果 X = 0，则 X := len(string) + 1
4. X := X - 1
5. 如果 X > 0，则将 substr(s, 1, X) 插入表中
6. 如果 X > 0，则 s := substr(s, X+1, len(s))

我没有对其进行测试，并且有明显的优化方法（例如 - 您可以存储当前解析部分的“左端索引”，而不是将子字符串分配回 s。

但是有更好的方法——用纯 sql 来做。 不幸的是，我不知道你的oracle版本是否支持所有功能，但试试这个选择：

with 
my_input_string as (
   select 'my,delimited,,,,,,input,string' s from dual
),
string_to_rows as (
   select trim(regexp_substr(s, '[^,]+', 1, LEVEL)) col 
    from my_input_string
 connect by instr(my_input_string.s, ',', 1, LEVEL - 1) > 0
)
select *
  from string_to_rows
 where col is not null

如果它有效（我的意思是“有效” - 返回四行），只需在插入中使用它。 用过程的参数替换硬编码的字符串，就是这样。