Oracle 函数返回空值？

Question

这开始让我发疯，我找不到这不起作用的原因！

表格上有触发器，因此 cityID 和 postcodeID 会自动填充。该函数的目的是找到一个同名的城市并返回其 ID，否则将其添加到表中并返回新 ID。

CREATE OR REPLACE FUNCTION resolveCity(cityNameIn IN VARCHAR2)
RETURN NUMBER AS
    cityIDOut NUMBER;
BEGIN
    SELECT cityID
    INTO cityIDOut
    FROM tblCities
    WHERE cityName = cityNameIn;

    IF cityIDOut IS NULL THEN
        -- Add this city to the list
        INSERT INTO tblCities (cityName)
        VALUES (cityNameIn)
        RETURNING cityID INTO cityIDOut;
    END IF;

    RETURN(cityIDOut);
END;
/

Answer 1

如果 PL/SQL 中的 SELECT 失败，则会引发 NO_DATA_FOUND 异常。在这种情况下，函数中没有处理程序，所以它被提升到一个外部处理程序 - 显然没有，所以它掉在地板上并丢失了。

我建议你将你的函数重写为：

CREATE OR REPLACE FUNCTION resolveCity(cityNameIn IN VARCHAR2)
RETURN NUMBER AS
    cityIDOut NUMBER;
BEGIN
  BEGIN
    SELECT cityID
      INTO cityIDOut
      FROM tblCities
      WHERE cityName = cityNameIn;
  EXCEPTION
    WHEN NO_DATA_FOUND THEN
      -- Add this city to the list
      INSERT INTO tblCities (cityName)
        VALUES (cityNameIn)
        RETURNING cityID INTO cityIDOut;
  END;

  RETURN(cityIDOut);
END;

祝你好运。