VBA SQL 缺少 WHERE 子句的最后一个条件

Question

我已经拔掉了我遗漏的最后一点，试图获得我认为通过 VBA 运行的相当简单的 SQL 语句。当语句的字符串编译时，它会切断 WHERE 子句的最后一个条件，我不知道如何修复它。请帮忙！

我的 SQL 字符串如下所示：

sSQL = "UPDATE Allocations SET WithdrawalDate =" & dThisWithdrawDate & ",Notes = '" & sNotes & "' WHERE StaffID =" & lID & " AND PatientID = " & lThisPatientID & ";"

字符串与 StaffID 变量一起编译并切断子句的 AND 部分。我做错了什么？

Answer 1

@Kostas 建议的另一种方法是使用参数：

Sub Test()

    Dim dThisWithdrawDate As Date
    Dim sNotes As String
    Dim lID As Long
    Dim lThisPatientID As Long

    dThisWithdrawDate = DateSerial(2018, 6, 10)
    sNotes = "This note's not possible without hassle in string concat."
    lID = 1
    lThisPatientID = 2

    With CurrentDb.CreateQueryDef("", _
        "Parameters WithdrawDate DateTime, PatientNotes Text(255), " & _
        "StaffIdentifier Long, PatientIdentifier Long; " & _
        "UPDATE Allocations SET WithdrawalDate = WithDrawDate, Notes = PatientNotes " & _
        "WHERE StaffID = StaffIdentifier AND PatientID = PatientIdentifier")

        .Parameters("WithdrawDate") = dThisWithdrawDate
        .Parameters("PatientNotes") = sNotes
        .Parameters("StaffIdentifier") = lID
        .Parameters("PatientIdentifier") = lThisPatientID
        .Execute

    End With

End Sub

如果使用存储查询，您也可以使用类似：With db.QueryDefs("DML_Update_AllocationTable")。

Answer 2

尝试以某种可复制的方式进行：

Public Sub TestMe()

    Dim sSql As String
    Dim dThisWithdrawDate As String: dThisWithdrawDate = "foo"
    Dim sNotes As String: sNotes = "bar"
    Dim lID As Long: lID = 5
    Dim lThisPatientID As Long: lThisPatientID = 10

    sSql = "UPDATE Allocations SET WithdrawalDate =" & dThisWithdrawDate & ",Notes = '" & sNotes & "' WHERE StaffID =" & lID & " AND PatientID = " & lThisPatientID & ";"
    Debug.Print sSql

End Sub

上面的代码打印出来：

UPDATE Allocations SET WithdrawalDate =foo,Notes = 'bar' WHERE StaffID =5 AND PatientID = 10;

因此，AND 子句从其他地方被切断。