如何使用 DataReader 提取 SQL Schema

Question

我们是否可以从表中提取 SQL 数据库架构？

以下是我的代码，但现在我可以像

一样提取整个架构

Create Table Employee(code int, name blah blah...)

Dim sqlQuery As String
Dim textInsertQueryLine As String
Dim tableSchema As DataTable
Dim tableField As DataRow
Dim tableProperty As DataColumn

Dim SourceConn As New SqlConnection(sourceDBPath)
Dim DestinationConn As New SqlConnection(destinationDBPath)

SourceConn.Open()
DestinationConn.Open()

sqlQuery = "SELECT name FROM sys.tables"

Dim cmdX As New SqlCommand(sqlQuery, SourceConn)
Dim readerX As SqlDataReader = cmdX.ExecuteReader

Do While readerX.Read

    Dim cmdY As New SqlCommand(sqlQuery, DestinationConn)
    Dim readerY As SqlDataReader = cmdY.ExecuteReader

    Do While readerY.Read

        If readerX.GetString(0) = readerY.GetString(0) Then
            txtConsoleView.AppendText(readerX.GetString(0) + "Matched. " + vbCrLf)
        Else

            tableSchema = readerX.GetSchemaTable()

            txtConsoleView.AppendText(tableSchema.ToString + vbCrLf)
        End If

    Loop
    readerY.Close()
Loop
readerX.Close()

SourceConn.Close()
DestinationConn.Close()

Answer 1

这是我从头开始编写的一种工作方法，因此没有经过真正的测试。它使用DataReader.GetSchemaTable() 列出每个表的所有列：

您可以使用这些类来映射架构信息，您可以根据this list添加更多：

Public Class Table
    Public Property DatabaseName As String
    Public Property TableName As String
    Public Property Schema As String
    Public Property FullName As String
    Public Property AllColumns As New List(Of TableColumn)

    Public Overrides Function ToString() As String
        Return FullName
    End Function
End Class

Public Class TableColumn
    Public Property ColumnName As String
    Public Property DataType As Type
    Public Property Size As Int32
    Public Property ColumnOrdinal As Int32
    Public Property AllowDBNull As Boolean
    Public Property IsAutoIncrement As Boolean

    Public Overrides Function ToString() As String
        Return String.Format("{0}({1})", ColumnName, DataType.ToString())
    End Function
End Class

此代码将所有表及其所有列读入一个列表：

Dim allTables As New List(Of Table)

Using con As New SqlConnection(My.Settings.RM2ConnectionString) ' use your connection-string '
    Using sysTblCommand As New SqlCommand("SELECT [Database]=DB_NAME(DB_ID()),FullName='['+SCHEMA_NAME(schema_id)+'].['+name+']',[Schema]=SCHEMA_NAME(schema_id),Name  FROM sys.tables ORDER BY schema_id,name", con)
        con.Open()
        Using readerSys = sysTblCommand.ExecuteReader()
            While readerSys.Read()
                Dim table As New Table()
                table.DatabaseName = readerSys.GetString(0)
                table.FullName = readerSys.GetString(1)
                table.Schema = readerSys.GetString(2)
                table.TableName = readerSys.GetString(3)
                allTables.Add(table)
            End While
        End Using
        For Each table In allTables
            Using tblCommand As New SqlCommand("SELECT * FROM " & table.ToString(), con)
                tblCommand.CommandTimeout = 0
                Using rd = tblCommand.ExecuteReader()
                    Dim schemaTable As DataTable = rd.GetSchemaTable()
                    For Each row As DataRow In schemaTable.Rows
                        Dim col As New TableColumn()
                        col.ColumnName = row.Field(Of String)("ColumnName")
                        col.DataType = row.Field(Of Type)("DataType")
                        col.Size = row.Field(Of Int32)("ColumnSize")
                        col.ColumnOrdinal = row.Field(Of Int32)("ColumnOrdinal")
                        col.AllowDBNull = row.Field(Of Boolean)("AllowDBNull")
                        col.IsAutoIncrement = row.Field(Of Boolean)("IsAutoIncrement")
                        table.AllColumns.Add(col)
                    Next
                End Using
            End Using
        Next
    End Using
End Using

Answer 2

从数据库中获取模式信息是通过模式发现过程完成的。

架构发现允许应用程序请求托管提供程序查找并返回有关给定数据库的数据库架构（也称为元数据）的信息。

不同的数据库架构元素（例如表、列和存储过程）通过架构集合公开。

每个架构集合都包含特定于所使用的提供程序的各种架构信息。

每个 .NET Framework 托管提供程序都在 Connection 类中实现 GetSchema 方法，并且从 GetSchema 方法返回的架构信息以 DataTable 的形式出现。

GetSchema 方法是一个重载方法，它提供可选参数来指定要返回的架构集合，并限制返回的信息量。

更多信息：MSDN LINK

例子：

Imports System.Data.SqlClient

Module Module1
   Sub Main()
      Dim connectionString As String = GetConnectionString()
      Using connection As New SqlConnection(connectionString)
         'Connect to the database then retrieve the schema information.
         connection.Open()
         Dim table As DataTable = connection.GetSchema("Tables")

         ' Display the contents of the table.
         DisplayData(table)
         Console.WriteLine("Press any key to continue.")
         Console.ReadKey()
      End Using
   End Sub

   Private Function GetConnectionString() As String
      ' To avoid storing the connection string in your code,  
      ' you can retrieve it from a configuration file.
      Return "Data Source=(local);Database=AdventureWorks;" _
         & "Integrated Security=true;"
   End Function

   Private Sub DisplayData(ByVal table As DataTable)
      For Each row As DataRow In table.Rows
         For Each col As DataColumn In table.Columns
            Console.WriteLine("{0} = {1}", col.ColumnName, row(col))
         Next
         Console.WriteLine("============================")
      Next
   End Sub
End Module