pdf的Ghostscript合并导致方向翻转

Question

pdf 的 Ghostscript 合并导致方向翻转

我正在使用与此 SO 问题类似的方法： How to merge two postscript files together?

在合并后的 PDF 中，每几页都会上下翻转。我还没有看到它在其他任何地方提到过这种症状。合并单个麻烦的 pdf 仍然会颠倒方向。

@echo off
REM FILE: merge.bat

call :merge 1 155 out.pdf
pause
goto :eof

REM MERGE PDFs
REM @param # of first file in sequence
REM @param # of last file in sequence
REM @param new file of merged pdf
goto :eof
:merge
SET START=%1
SET END=%2
SET OUT=%3
echo START=%START%
echo END=%END%
echo OUT=%OUT%
echo.
SET CMD="c:\Program Files\gs\gs9.01\bin\gswin32c.exe"
SET INPUT_DIR=c:\input
SET CMD_ARGS=args.bat
echo Generating args file...
(echo.|set /p="-dBATCH -dNOPAUSE -q -sDEVICE=pdfwrite -sOutputFile=%OUT% ") > %CMD_ARGS%
for /L %%G IN (%START%,1,%END%) do (
  (echo.|set /p=" "%INPUT_DIR%\%%G.pdf" ") >> %CMD_ARGS%
)
echo. >> %CMD_ARGS%
del %OUT%
if exist %OUT% goto :error
echo Executing command...
%CMD% @%CMD_ARGS%
del %CMD_ARGS%
echo Done.
if not exist %OUT% goto :error
goto :eof

:error
echo Error processing command.
goto :eof

Answer 1

TJR，您可以尝试在 Ghostscript 调用中添加以下命令行参数之一：

-dAutoRotatePages=/None
-dAutoRotatePages=/All 
-dAutoRotatePages=/PageByPage

如果这不会改变结果，试试这个：

gswin32c.exe ^
 -o c:/path/to/output.pdf ^
 -sDEVICE=pdfwrite ^
 -dPDFSettings=/prepress ^
 -dAutoRotatePages=/None ^
 -c "<</Orientation 0>> setpagedevice" ^
 -f /path/to/first.pdf ^
    /path/to/second.pdf ^
    /path/to/third.pdf 

带有/Orientation 0 的部分应将所有页面变为纵向。使用3 应该使它成为风景（1 用于海景，2 用于倒置）。

但是，这不会可靠地工作，因为您的（某些）源文件可能包含自己奇怪的页面方向和旋转设置。在这种情况下，只有对源文件进行“修复”才能解决此问题....