数组文字Google表格中不同大小的行答案

【问题标题】：Different size rows in array literal Google Sheets数组文字Google表格中不同大小的行
【发布时间】：2019-10-06 18:14:30
【问题描述】：

我正在尝试在 Google 表格中执行此操作：

={{1}; {1, 1}}

并得到错误在ARRAY_LITERAL，一个数组文字缺少一个或多个行的值。

我的最终目标是做这样的事情：

"title A"
IMPORTRANGE("spreadsheet A", A:Z)...
"title B"
IMPORTRANGE("spreadsheet B", A:Z)...
"title C"
IMPORTRANGE("spreadsheet C", A:Z)...
etc...

导入范围最好也忽略空的 A 行。每个电子表格都有不同数量的列和行，并且它们都会不时更改。

【问题讨论】：

标签： arrays google-sheets google-sheets-formula google-sheets-query importrange

【解决方案1】：

你需要这样做：

={{1, ""}; {1, 1}}

对于您的 IMPORTRANGE 示例，它将类似于：

={{"title A","","","","","","","","","","","","","","","","","","","","","","","","",""}; 
 IMPORTRANGE("ID", "Sheet1A:Z")}

但为了避免重复空单元格，您可以这样做：

={{"title A", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
 IMPORTRANGE("ID", "Sheet1A:Z")}

这意味着：重复 (REPT) 数字 12 25 次（因为您需要覆盖范围 B:Z）这将为您提供数字：12121212121212121212121212121212121212121212121212 现在您将 SPLIT 每次出现数字 2因此，您将在 25 个单元格中获得 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1。为了摆脱那些 1，你将 SUBSTITUTE 无所事事地排名第一

或者像这样：

=ARRAYFORMULA({{"title A", SUBSTITUTE(COLUMN(B:Z)^0, 1, )};
 IMPORTRANGE("ID", "Sheet1A:Z")})

在尝试您的联合公式之前，不要忘记分别运行每个 IMPORTRANGE。您需要允许访问以将您的电子表格与每个唯一的 IMPORTRANGE 连接起来

={{"title A", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
 IMPORTRANGE("ID1", "Sheet1A:Z");
  {"title B", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
 IMPORTRANGE("ID2", "Sheet1A:Z");
  {"title C", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
 IMPORTRANGE("ID3", "Sheet1A:Z")}

要摆脱空行，您可以执行以下操作：

=QUERY({{"title A", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
        IMPORTRANGE("ID1", "Sheet1A:Z");
        {"title B", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
        IMPORTRANGE("ID2", "Sheet1A:Z");
        {"title C", SUBSTITUTE(SPLIT(REPT(12, 25), 2), 1, )};
        IMPORTRANGE("ID3", "Sheet1A:Z")}, 
 "where Col1 is not null", 0)

【讨论】：

为什么需要SUBSTITUTE？为什么不直接做SPLIT(REPT(" ,"), ",")
@user12341234 删除那些 1。