如何在 Basic 中使用 LibreOffice 功能？答案

【问题标题】：How to use LibreOffice functions into Basic?如何在 Basic 中使用 LibreOffice 功能？
【发布时间】：2015-05-13 13:33:33
【问题描述】：

我已经asked here 告知了这样做的好方法。

现在我正在尝试以下代码found here，并得到一些意外错误。

我想我没有以正确的方式使用它。有什么想法吗？

Sub Main 
    Dim aResult 
    Dim aFunc 
    Dim oRange 

    aFunc = GetProcessServiceManager().createInstance("com.sun.star.sheet.FunctionAccess") 

    aResult = aFunc.callFunction("SUM", Array(1, 2, 3))
    ' ---- Works OK
    Print aResult 

    aResult = aFunc.callFunction("MDETERM", Array(2, 5, 8)) 
    ' ---- IllegalArgumentException
    Print aResult 

    oRange = ThisComponent.sheets(0).getcellrangebyname("B4:B6") 
    aResult = aFunc.callFunction("ZTEST", Array(oRange, 2.5, 1.0)) 
    ' ---- IllegalArgumentException
    Print aResult 
End Sub

【问题讨论】：

你得到了哪些“意外错误”？
那些是 IllegalArgumentException，正如我在代码中提到的。它们涉及 cmets 上方的线。

标签： libreoffice basic libreoffice-calc libreoffice-basic

【解决方案1】：

MDETERM 需要一个方阵。

而ZTEST 仅在该范围内有值时才有效。

Sub Main 

    Dim oFunc as Object
    Dim vResult as Variant
    Dim oRange as Object
    Dim bDoZTEST as Boolean
    Dim aSubArray as Variant
    Dim vValue as Variant

    oFunc = GetProcessServiceManager().createInstance("com.sun.star.sheet.FunctionAccess") 

    vResult = oFunc.callFunction("SUM", Array(1, 2, 3))
    Print vResult 

    vResult = oFunc.callFunction("MDETERM", Array(Array(Array(2, 5, 8), Array(1, 4, 3), Array(9, 7, 6)))) 
    Print vResult 

    oRange = ThisComponent.sheets(0).getCellRangeByName("B4:B6") 
    bDoZTEST = true
    vResult = Empty
    for each aSubArray in oRange.DataArray
     for each vValue in aSubArray
      if not isNumeric(vValue) then bDoZTEST = false
     next
    next
    if bDoZTEST then vResult = oFunc.callFunction("ZTEST", Array(oRange, 2.5, 1.0)) 
    Print vResult 

End Sub

【讨论】：