Delphi 2010+和只读记录中的“左侧不能分配给”：可以禁用吗？

Question

我知道what changed。我知道为什么。但是..

TComplicatedCallMaker = record
    Param1: TRecordType;
    Param2: TRecordType;
    {...}
    Param15: TRecordType;
    procedure Call;
end;

function ComplicatedCall: TComplicatedCallMaker;
begin
 { Fill default param values }
end;

procedure DoingSomeWorkHere;
begin
  with ComplicatedCall do begin
    Param7 := Value7;
    Param12 := Value12;
    Call;
  end;
end;

这在 Delphi 2010 之前完美运行。这是一种非常有用的技术，用于进行接受大量参数但通常只需要两个或三个参数的调用。但绝不是相同的。

现在它给出了......你猜怎么着？

E2064: Left side cannot be assigned to.

不能以某种方式禁用这种有用的新行为吗？关于如何修改模式以使其正常工作的任何想法？

因为严重的是，无缘无故失去了如此方便的技术（并重写了一堆代码）......

Answer 1

我觉得这有点令人惊讶，但既然你说它确实有效，我相信你是对的。我猜这个改变是在没有考虑记录方法的情况下做出的。如果没有调用方法的能力，那么这种构造将毫无意义。

无论如何，编译器不会让你摆脱这个问题，所以你必须这样做：

type
  TRecordType = record end;
  TComplicatedCallMaker = record
    Param1: TRecordType;
    procedure Call;
  end;

function ComplicatedCall: TComplicatedCallMaker;
begin
 { Fill default param values }
end;

procedure DoingSomeWorkHere(const Value: TRecordType);
var
  CallMaker: TComplicatedCallMaker;
begin
  CallMaker := ComplicatedCall;
  with CallMaker do begin
    Param1 := Value;
    Call;
  end;
end;

Answer 2

我……我想我做到了

我希望 Delphi 开发人员看看他们让他们的程序员做什么！

type
  PCallMaker = ^TCallMaker;
  TCallMaker = record
    Param1: integer;
    Param2: integer;
    function This: PCallMaker; inline;
    procedure Call; inline;
  end;

function TCallMaker.This: PCallMaker;
begin
  Result := @Self;
 { Record functions HAVE to have correct self-pointer,
  or they wouldn’t be able to modify data. }
end;

procedure TCallMaker.Call;
begin
  writeln(Param1, ' ', Param2);
end;

function CallMaker: TCallMaker; inline
begin
  Result.Param1 := 0;
  Result.Param2 := 0;
end;

procedure DoingSomeWorkHere;
var cm: TCallMaker;
begin
 {Test the assumption that cm is consistent}
  cm := CallMaker;
  if cm.This <> @cm then
    raise Exception.Create('This wasn''t our lucky day.');

 {Make a call}
  with CallMaker.This^ do begin
    Param1 := 100;
    Param2 := 500;
    Call;
  end;
end;

这可行，保留了旧版本的所有优点（速度、简单、调用开销小），但这种方法没有任何隐藏的问题吗？