用于命名范围的 UDF 函数

Question

我需要一个小 UDF 来命名 Excel 中的范围，但它不断返回 #VALUE 错误。与 sub 做同样的事情就像一个魅力，但不是我想要的，因为我想命名大量的范围。 首先是子：

Sub setNamedRanges()
    ' input values
    inputRange = "A4"
    newName = "Tank101"

    ' removing spaces from the name
    newName = Replace(newName, " ", "")

    ' write the name
    Range(inputRange).name = newName
End Sub

现在与函数相同（inputRange = "A4" 和 newName = "Tank101"），它应该在完成后返回“成功”但根本不起作用：

Function setNamedRange(inputRange, newName)

    ' removing spaces from the name
    newName = Replace(newName, " ", "")

    ' write the name
    Range(inputRange).name = newName

    setNamedRange = "succesful"
End Function

我做错了什么？将具有所需值的数组读入 sub 肯定会起作用，但不能提供完整的功能。

Answer 1

函数不能更改工作簿。范围是工作簿/工作表属性，因此不能由函数更改。函数可以将结果返回到工作表，但这不是属性，所以没关系。另一方面， subs 不能返回任何东西，但他们可以修改属性。

Answer 2

你可以试试下面的代码。效果很好：

Sub setNamedRanges()
    Dim newName As String
    newName = "Tank101"
    Dim inputRange As Range
    Set inputRange = Range("A4")
    inputRange.name = newName
End Sub

如果您有任何疑问，请告诉我。

问候

Answer 3

好的，你可以试试下面的其他方法：

Sub Button1_Click()
   Call ChangeValue("Tank101", "Alibaba")
End Sub

Sub ChangeValue(cellAddress, newValue)
    Dim inputRange As Range
    Set inputRange = Range(cellAddress)
    inputRange.Name = newValue
End Sub

如果您有任何疑问，请告诉我。

Answer 4

在 Marks 答案的帮助下，我为我的问题找到了以下解决方案，请参阅下面的解决方案。它有点长而且不是直截了当的，但它确实有效。调用

giveNameToRange("Tank101")

在单元格内，给这个单元格命名为“Tank 101”。代码是：

Private Declare Function SetTimer Lib "user32" ( _
      ByVal HWnd As Long, _
      ByVal nIDEvent As Long, _
      ByVal uElapse As Long, _
      ByVal lpTimerFunc As Long _
   ) As Long

Private Declare Function KillTimer Lib "user32" ( _
      ByVal HWnd As Long, _
      ByVal nIDEvent As Long _
   ) As Long

Private mCalculatedCells As Collection
Private mWindowsTimerID As Long
Private mApplicationTimerTime As Date

Public Function giveNameToRange(newName) As String

' This is a UDF that returns the sum of two numbers and starts a windows timer
' that starts a second Appliction.OnTime timer that performs activities not
' allowed in a UDF. Do not make this UDF volatile, pass any volatile functions
' to it, or pass any cells containing volatile formulas/functions or
' uncontrolled looping will start.

   newName = Replace(newName, " ", "")
   giveNameToRange = newName

   ' Cache the caller's reference so it can be dealt with in a non-UDF routine
   If mCalculatedCells Is Nothing Then Set mCalculatedCells = New Collection
   On Error Resume Next
   mCalculatedCells.Add Application.Caller, Application.Caller.Address
   On Error GoTo 0

   ' Setting/resetting the timer should be the last action taken in the UDF
   If mWindowsTimerID <> 0 Then KillTimer 0&, mWindowsTimerID
   mWindowsTimerID = SetTimer(0&, 0&, 1, AddressOf AfterUDFRoutine1)

End Function

Public Sub AfterUDFRoutine1()

' This is the first of two timer routines. This one is called by the Windows
' timer. Since a Windows timer cannot run code if a cell is being edited or a
' dialog is open this routine schedules a second safe timer using
' Application.OnTime which is ignored in a UDF.

   ' Stop the Windows timer
   On Error Resume Next
   KillTimer 0&, mWindowsTimerID
   On Error GoTo 0
   mWindowsTimerID = 0

   ' Cancel any previous OnTime timers
   If mApplicationTimerTime <> 0 Then
      On Error Resume Next
      Application.OnTime mApplicationTimerTime, "AfterUDFRoutine2", , False
      On Error GoTo 0
   End If

   ' Schedule timer
   mApplicationTimerTime = Now
   Application.OnTime mApplicationTimerTime, "AfterUDFRoutine2"

End Sub

Public Sub AfterUDFRoutine2()

' This is the second of two timer routines. Because this timer routine is
' triggered by Application.OnTime it is safe, i.e., Excel will not allow the
' timer to fire unless the environment is safe (no open model dialogs or cell
' being edited).

   Dim Cell As Range

   ' Do tasks not allowed in a UDF...
   Application.ScreenUpdating = False
   Application.Calculation = xlCalculationManual
   Do While mCalculatedCells.Count > 0
      Set Cell = mCalculatedCells(1)
      mCalculatedCells.Remove 1
      Cell.name = Cell.Value
   Loop
   Application.Calculation = xlCalculationAutomatic
   Application.ScreenUpdating = True
   End Sub