VB.Net 扩展对象 IExtenderProvider

Question

好的，我已经为此奋斗了几天，但我束手无策...我正在尝试通过扩展控件来添加一个在运行时在 PropertyGrid 中可见的可浏览属性。无论我做什么，iExtenderProvider 似乎都没有实际运行。

iExtenderProvider 位于第二个项目中，并在主项目中添加了一个引用。 （代码如下）

Imports System.ComponentModel
Imports System.Windows.Forms

Public Class ControlArray
             Inherits Component
             Implements IExtenderProvider
    <Browsable(True)> Public ReadOnly Property Count As Integer
        Get
            Return 0
        End Get
    End Property

    Public Function CanExtend(ByVal extendee As Object) As Boolean Implements IExtenderProvider.CanExtend
       Return TypeOf extendee Is Control
    End Function
End Class

然后我构建第二个项目，返回第一个项目，我的属性窗口中没有任何内容，我在代码中实例化一个控件，然后尝试找到我的“计数”属性，但那里没有任何内容。关于可能是什么问题的任何建议？

Answer 1

阅读答案之前

确保你知道：

扩展器提供程序是一个向其他组件提供属性的组件。扩展器提供者提供的属性实际上驻留在扩展器提供者对象本身中，因此不是它所修改的组件的真实属性。

在设计时，属性出现在属性窗口中。

在运行时，您不能通过组件本身访问该属性。相反，您可以在扩展器组件上调用 getter 和 setter 方法。

实现扩展提供程序

• 从Component 继承并实现IExtenderProvider 接口。
• 用ProvideProperty 属性装饰你的组件类，并引入提供的属性和目标控件类型。
• 在实现 CanExtend 方法时，为您要为其提供属性的每个控件类型返回 true。
• 为提供的属性实现 getter 和 setter 方法。

了解详情

• Extender Provider Overview
• IExtenderProvider
• How to: Implement a HelpLabel Extender Provider

示例

使用以下代码，您可以实现扩展器组件ControlExtender。当您构建代码并将ControlExtender 的实例放在表单上时，它会扩展所有控件并在属性网格中为您的控件添加SomeProperty on ControlExtender1 属性。

1. 在项目中添加Component并将其命名为ControlExtender
2. 然后在ControlExtender.vb 中使用这些代码

Imports System.ComponentModel
Imports System.Windows.Forms

<ProvideProperty("SomeProperty", GetType(Control))>
Public Class ControlExtender
    Inherits Component
    Implements IExtenderProvider
    Private controls As New Hashtable
    Public Function CanExtend(extendee As Object) As Boolean Implements IExtenderProvider.CanExtend
            Return TypeOf extendee Is Control
    End Function

    Public Function GetSomeProperty(control As Control) As String
        If controls.ContainsKey(control) Then
            Return DirectCast(controls(control), String)
        End If

        Return Nothing
    End Function
    Public Sub SetSomeProperty(control As Control, value As String)
        If (String.IsNullOrEmpty(value)) Then
            controls.Remove(control)
        Else
            controls(control) = value
        End If
    End Sub
End Class

注意：您也可以根据您的要求继承Control。但在大多数情况下，继承 Component 更有意义。