当文件在另一个进程中打开时，Inno Setup LoadStringFromFile 失败

Question

要检查数据库 (SQL Anywhere) 何时启动并准备好接收请求，我将数据库消息窗口输出到日志（文本）文件，然后尝试使用 LoadStringFromFile 读取它，然后我使用Pos 搜索特定文本。问题是这会失败（我假设），因为文件正在使用中。

Exec(strInstallPath + '\Bin32\dbeng17.exe', '-n ' + strEngineName + ' "' + strInstallPath + '\Database\Olympus.db" -n ' + strDatabaseName + ' -gdall -xtcpip -ti0 -c25p -ot "' + strTempPath + '\dbeng.log"', '', SW_HIDE,
  ewNoWait, intResultCode);
if not LoadStringFromFile(strTempPath + '\dbeng.log', astrDatabaseEngineLog) then
  begin
    Log('Loading string from file failed.');
  end;

我也尝试使用FileCopy 复制日志文件并尝试从文件副本中读取，但FileCopy 也失败了。

if not FileCopy(strTempPath + '\dbeng.log', strTempPath + '\dbengcopy.log', False) then
  begin
    Log('File copy failed.');
  end;

有什么方法可以从正在使用的文件中读取数据或其他方法吗？

Answer 1

生成数据库服务器时，请使用专为此目的设计的dbspawn 实用程序。您生成 dbspawn 以及要运行的 dbeng/dbsrv 命令，它会为您启动服务器。在数据库服务器启动、运行并准备好接受请求之前，dbspawn 实用程序不会返回，因此无需猜测，也无需读取控制台日志文件。

我不知道您运行的是哪个版本的 SQL Anywhere，但这里是 documentation for v17。在任何其他版本中都应该是相同的。

Answer 2

使用TFileStream.Create(FileName, fmOpenRead or fmShareDenyNone)。

在 Inno Setup 的 Unicode 版本（Inno Setup 6 的唯一版本）中，由于类的接口不好，它的使用很棘手。

function BufferToAnsi(const Buffer: string): AnsiString;
var
  W: Word;
  I: Integer;
begin
  SetLength(Result, Length(Buffer) * 2);
  for I := 1 to Length(Buffer) do
  begin
    W := Ord(Buffer[I]);
    Result[(I * 2)] := Chr(W shr 8); { high byte }
    Result[(I * 2) - 1] := Chr(Byte(W)); { low byte }
  end;
end;

function LoadStringFromLockedFile(const FileName: string; var S: AnsiString): Boolean;
var
  Buffer: string;
  Stream: TFileStream;
begin
  Result := True;
  try
    Stream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyNone);
    try
      SetLength(Buffer, Stream.Size div 2);
      Stream.ReadBuffer(Buffer, Stream.Size);
      S := BufferToAnsi(Buffer);
    finally
      Stream.Free;
    end;
  except
    Result := False;
  end;
end;

---

代码基于TLama's code 发布在Read bytes from file at desired position with Inno Setup。