如何在 CoffeeScript 胖箭头回调中引用实际的“this”？

Question

标题说明了一切。当我在 CoffeeScript 中使用胖箭头时，它会在调用函数之前先存储this。例如：

class myClass
    constructor: ->
        element = $ "#id"
        element.click ->
            @myMethod(@value)
            return
        return

    myMethod: (c)->
        window.console.log(c)
        return

会产生

var myClass;

myClass = (function() {
  function myClass() {
    var element;
    element = $("#id");
    element.click(function() {
      this.myMethod(this.value);
    });
    return;
  }

  myClass.prototype.myMethod = function(c) {
    window.console.log(c);
  };

  return myClass;

})();

现在在 JavaScript 的第 8 行，this.myMethod 是错误的。在此范围内，this 指的是element，而不是类MyClass。

但是，如果在 CoffeeScript 的第 4 行，我将 element.click -> 替换为 element.click =>，JavaScript 中的第 8 行将变为 _this.myMethod(_this.val)，其中引用 myClass 的 this 在调用函数之前存储在 _this .但是_this.value 是未定义的，即使它已定义，我在这里尝试访问的对象也是element（在此函数范围内由实际的this 关键字引用）。

现在如何访问实际的this？

Answer 1

您至少可以通过三种方式实现您的目标。第一个是：

class myClass
    constructor: ->
        element = $ "#id"
        element.click =>
            @myMethod(element.value)
            return
        return

    myMethod: (c) ->
        window.console.log(c)
        return

第二个：

class myClass
    constructor: ->
        element = $ "#id"
        myMethodCallback = (c) => @myMethod(c)
        element.click ->
            myMethodCallback(@value)
            return
        return

    myMethod: (c) ->
        window.console.log(c)
        return

第三个如下图所示。不过我不确定 jQuery API 的使用情况，所以最好检查一下appropriate docs page。

class myClass
    constructor: ->
        element = $ "#id"
        element.click (event) =>
            @myMethod(event.target.value)
            return
        return

    myMethod: (c) ->
        window.console.log(c)
        return

我更喜欢第一种方式，因为它似乎更直接。 这个或另一个，但您需要决定您希望在 element.click 回调范围内拥有“哪个 this”。不能同时访问两个“thises”。

顺便说一句。所有这些返回语句似乎都是不必要的。最短的工作解决方案如下所示：

class myClass
    constructor: ->
        element = $ "#id"
        element.click => @myMethod(element.value)

    myMethod: (c) -> window.console.log(c)