咖啡脚本中的 switch case 语句

Question

我有几个不同的按钮调用相同的函数，我希望将它们包装在 switch 语句中，而不是使用一堆 else if 条件。任何帮助都会很棒！！！

events:
"click .red, .blue, #black, #yellow" : "openOverlay"

openOverlay: (e) ->
  e.preventDefault()
  e.stopPropagation()

target = $(e.currentTarget)

# the view should be opened
view = 
  if target.hasClass 'red' then new App.RedView
  else if target.hasClass 'blue' then new App.BlueView
  else if target.is '#black' then new App.BlackView
  else
    null

# Open the view
App.router.overlays.add view: view if view?

Answer 1

CoffeeScript 中有两种形式的switch：

switch expr
    when expr1 then ...
    when expr2 then ...
    ...
    else ...

和：

switch
    when expr1 then ...
    when expr2 then ...
    ...
    else ...

第二种形式可能对您有所帮助：

view = switch
  when target.hasClass 'red' then new App.RedView
  when target.hasClass 'blue' then new App.BlueView
  when target.is '#black' then new App.BlackView
  else null

如果undefined 是view 的可接受值，您可以省略else null。您还可以将逻辑包装在（显式）函数中：

viewFor = (target) ->
    # There are lots of ways to do this...
    return new App.RedView   if(target.hasClass 'red')
    return new App.BlueView  if(target.hasClass 'blue')
    return new App.BlackView if(target.is '#black')
    null

view = viewFor target

给你的逻辑一个名字（即将它包装在一个函数中）通常有助于澄清你的代码。

Answer 2

除了the accepted answer中的细节，CoffeeScript中的switch语句还支持,提供多个匹配结果：

switch someVar
    when val3, val4 then ...
    else ...

或（如果您的语句有多行）：

switch someVar
    when val3, val4
        ...
    else
        ...