VB.NET - 检查子节点是否在 TreeView 中选中

Question

我正在使用 Visual Basic .NET 2013，我想知道在树视图中检查了哪些子节点。我不检查父节点，因为复选框仅在子节点中（我在父节点中禁用了复选框，因此它们不会出现）。

目前我正在使用我找到的一种解决方案：

Private Sub TreeView1_AfterCheck(sender As Object, e As TreeViewEventArgs) Handles TreeView1.AfterCheck
    Dim childNodeCK As TreeNode = e.Node

    If childNodeCK.Checked = True Then
        If e.Node.Parent Is Nothing = False Then 'detects a Child Node
            TextBox1.Text = TextBox1.Text & childNodeCK.Text
            MessageBox.Show("Checked: " & childNodeCK.Text)
        End If
    End If

    If childNodeCK.Checked = False Then
        If e.Node.Parent Is Nothing = False Then
            MessageBox.Show("Unchecked: " & childNodeCK.Text)
        End If
    End If
End Sub

但我想知道是否有其他解决方案，类似这样（以下代码没有显示任何内容，因为当我单击按钮运行它时，没有任何反应）：

For Each childNode As System.Windows.Forms.TreeNode In TreeView1.Nodes
        If childNode.Checked = True Then
            MessageBox.Show(childNode.Text)
        End If 
Next

因为想法是单击一个按钮并获取当时检查的子节点的名称（文本）。所以我想我必须从头到尾一个一个地检查，如果检查了子节点然后执行一些代码。

Answer 1

要获取所有选中的节点，您必须使用递归函数或堆叠列表。我更喜欢后者：

Private Function GetCheckedNodes() As List(Of TreeNode)
  Dim result As New List(Of TreeNode)

  'Get the root nodes
  Dim nodes As New Stack(Of TreeNode)
  For Each tn As TreeNode In TreeView1.Nodes
    nodes.Push(tn)
  Next

  'Check each node and it's children
  While nodes.Count > 0
    Dim popNode As TreeNode = nodes.Pop
    If popNode.Checked Then
      result.Add(popNode)
    End If
    For Each tn As TreeNode In popNode.Nodes
      nodes.Push(tn)
    Next
  End While

  Return result
End Function

然后使用它：

For Each tn As TreeNode In GetCheckedNodes()
  MessageBox.Show(tn.Text)
Next