BusyIndi​​cator 不显示

Question

我想在一个漫长的过程中显示BusyIndicator。问题是当我让它运行时它不显示，然后在过程完成时显示。根据文档

忙碌指示符应用于指示正​​在加载内容时的活动，或者 UI 被阻塞以等待资源可用。

我创建了一个基于原始代码的最小代码

Window {
    id: win
    width: 300
    height: 300

    property bool run : false

    Rectangle {
        anchors.fill: parent
        BusyIndicator {
            anchors.centerIn: parent
            running: run
        }

        MouseArea {
            anchors.fill: parent
            onClicked: {
                run = true
                for(var a=0;a<1000000;a++) { console.log(a) }
                run = false
            }
        }
    }
}

因此，当单击Rectangle 时，我想在计算完成之前显示BusyIndicator。

例如，我在这里使用了 for 循环。在实际场景中，我通过ContextProperty 调用一个函数（将大约1000 行插入数据库）。但在这种情况下，BusyIndicator 也不会显示。

我做对了吗？或者最好的方法是什么？

Answer 1

您无法查看您的BusyIndicator，因为onClicked 处理程序中的长时间操作会阻塞应用程序GUI 并且指示器不会更新。您应该在不同的线程中运行此类操作以避免冻结 GUI。简单例子：

QML

Window {
    id: win
    width: 300
    height: 300

    property bool run : false

    Rectangle {
        anchors.fill: parent
        BusyIndicator {
            id: busy
            anchors.centerIn: parent
            running: win.run
        }

        MouseArea {
            anchors.fill: parent
            onClicked: {
                win.run = true
                thread.sendMessage({run : true});
            }
        }

        WorkerScript {
            id: thread
            source: "handler.js"
            onMessage: {
                win.run = messageObject.run;
            }
        }
    }
}

handle.js

WorkerScript.onMessage = function(message) {
    if(message.run === true) {
        for(var a=0;a<1000000;a++) { console.log(a) }
    }
    WorkerScript.sendMessage({run : false});
}

Answer 2

有一种方法可以使用QQuickWindow 的afterSynchronizing 信号：

import QtQuick 2.4
import QtQuick.Controls 1.3

ApplicationWindow {
    width: 400
    height: 400
    visible: true

    Component.onCompleted: print(Qt.formatDateTime(new Date(), "mm:ss:zzz"), "QML loaded")

    onAfterSynchronizing: {
        print(Qt.formatDateTime(new Date(), "mm:ss:zzz"), "Window content rendered")
        if (!loader.item) {
            loader.active = true
        }
    }

    Item {
        anchors.fill: parent

        BusyIndicator {
            running: !loader.item
            anchors.centerIn: parent
        }

        Loader {
            id: loader
            active: false
            anchors.fill: parent
            sourceComponent: Text {
                wrapMode: Text.Wrap

                Component.onCompleted: {
                    for (var i = 0; i < 500; ++i) {
                        text += "Hello, ";
                    }
                }
            }
        }
    }
}

这个想法是使用Loader 来控制何时发生昂贵的操作。您还可以通过Qt.createQmlObject() 或Qt.createComponent() 使用动态加载的组件，将组件动态加载到单独的文件中。

如果你运行这个例子，你会看到你得到以下输出：

qml：58:12:356 QML 已加载
qml: 58:12:608 呈现的窗口内容

我们使用QQuickWindow 的afterSynchronizing 信号来了解窗口内容何时显示，并且仅在第一次对其进行操作（通过if (!loader.item)）。

当信号最初发出时，我们可以确定BusyIndicator 已经开始了它的动画，所以用户实际上会看到一个旋转的图标。

一旦Loader 完成加载文本，其item 属性将变为非空，BusyIndicator 将消失。

Answer 3

今天遇到同样的问题！我将假设您正在通过名为 busy 的 C++ 属性控制您的 BusyIndicator。您在计算之前将busy 设置为true，之后设置为false。这样做为我解决了这个问题。这不是一个非常优雅的解决方案，但它确实有效：

QML

BusyIndicator {
    running: CPPModule.busy
}

CPP

void CPPModule::setBusy(const bool &busy)
{
    m_busy = busy;
    emit busyChanged();
}
void CPPModule::InsertIntoDB()
{
    setBusy(true);
    QThread::msleep(50);
    QCoreApplication::processEvents();
    /*
    very Long Operation
    */
    setBusy(false);
}