如何在不重复代码的情况下执行两个不同的 Foreach 循环

Question

我有一个数组散列和一个普通数组，根据情况（即用户在程序运行时选择的选项），只会定义其中一个。

演示问题的示例代码：

my %hashofarrays;
my @array;

#...
#Some code between here where either %hashofarrays or @array gets defined
#...

if (defined @array) {

    foreach my $var1 (@array) {
        print "var1 is: $var1\n";
        call_subroutine($var1);
        print "Something else is printed";
        call_anothersubroutine($var1);
        call_differentsubroutine($var1);
    }

} 

if (defined %hashofarrays) {

    foreach my $key (keys %hashofarrays) {
        print "the key is: $key\n";
        foreach my $var1 (@{$hashofarrays{$key}}) {
            call_subroutine($var1);
            print "Something else is printed";
            call_anothersubroutine($var1);
            call_differentsubroutine($var1);
        }
    }
}
   

正如您在上面的代码中看到的，取决于是否定义了@array 或是否定义了%hashofarrays，它将运行相应的if 语句。

问题：

但问题在于以下代码行在两个 if 语句中重复：

    call_subroutine($var1);
    print "Something else is printed";
    call_anothersubroutine($var1);
    call_differentsubroutine($var1);

显然，如果这些foreach 循环包含大量代码，则意味着大量代码将被重复。

当涉及到foreach 循环时，有什么方法/最好的方法是避免这种代码重复？

实际上，有没有办法执行以下操作：（我很清楚这段代码不起作用，但解释了我想要实现的目标）

if (defined @array) {
    foreach my $var1 (@array) {
} elsif (defined %hashofarrays) {
    foreach my $key (keys %hashofarrays) {
        print "the key is: $key\n";
        foreach my $var1 (@{$hashofarrays{$key}}) {

} #ending bracket of if statement

        call_subroutine($var1);
        print "Something else is printed";
        call_anothersubroutine($var1);
        call_differentsubroutine($var1); 

}  #ending bracket of whatever foreach loop is used

我很可能在这里忽略了一些显而易见的事情，但看不到这样做的合乎逻辑的方法？

Answer 1

首先，defined @array 和 defined %hashofarrays 是错误的。它们总是被定义的。您希望if (@array) 和if (keys %hashofarrays) 测试它们是否包含 元素。你甚至应该收到警告defined(@array) is deprecated！

你想要的是另一个子程序。

sub loop_body {  # just use some better name!
  my ($var) = @_;
  call_subroutine($var);
  print "Something else is printed";
  call_anothersubroutine($var);
  call_differentsubroutine($var);
}

然后：

if (@array) {
    foreach my $var1 (@array) {
        print "var1 is: $var1\n";
        loop_body($var1);
    }
} elsif (keys %hashofarrays) {
    foreach my $key (keys %hashofarrays) {
        print "the key is: $key\n";
        foreach my $var1 (@{$hashofarrays{$key}}) {
            loop_body($var1)
        }
    }
}

您还可以使用回调使您的解决方案更加灵活：

 sub loop_with_cb {
   my $cb = shift;
   for my $var (@_) {
     if ($cb) {
       local $_ = $var; # make $_ visible to the callback
       $cb->($var);
     }
     call_subroutine($var);
     print "Something else is printed";
     call_anothersubroutine($var);
     call_differentsubroutine($var);
   }
 }

然后：

if (@array) {
    loop_with_cb(
      sub { print "var1 is: $_\n" },
      @array,
    );
} elsif (keys %hashofarrays) {
    foreach my $key (keys %hashofarrays) {
        print "the key is: $key\n";
        loop_with_cb(undef, @{ $hashofarrays{$key} });
    }
}

Answer 2

使用其他功能可能会有所帮助，

if (@array) {
    my_func(\@array);
} 
if (%hashofarrays) {
    foreach my $key (keys %hashofarrays) {
        print "the key is: $key\n";
        my_func($hashofarrays{$key});
    }
}

sub my_func {
    my ($arr) = @_;

    foreach my $var1 (@$arr) {
        call_subroutine($var1);
        print "Something else is printed";
        call_anothersubroutine($var1);
        call_differentsubroutine($var1);
    }

}

Answer 3

正如 amon 所说，if (defined @array) 是错误的，但我什至不会打扰 if (@array)，除非您将拥有一个 else。您可以直接转到for (@array)，如果@array 为空，它将迭代零次，基本上就像if 一样跳过循环。

除此之外，您似乎想对@array 中的每个元素和%hash of arrays 中的每个键执行相同的操作，对吧？你甚至不需要sub：

for (@array, map { @$_ } values %hashofarrays) {
  my $var1 = $_;
  print "var is: $var1\n";
  call_subroutine($var1);
  print "Something else is printed";
  call_anothersubroutine($var1);
  call_differentsubroutine($var1);
}

编辑： 修改后的代码循环遍历 %hashofarrays 中数组的内容，而不是其键。这仍然与初始问题中的代码不完全匹配，因为它在循环遍历 hoa 时打印 $var1 而不是打印哈希键，但看起来 OP 的真实用例很有可能不会除了索引哈希之外，不要将密钥用于任何其他事情，在这种情况下，无论如何都不需要它（因为我们可以使用 values %hoa 代替）。