如何获取被调用的别名子程序的名称？

Question

我如何知道哪个别名被用来调用别名子程序？ caller 给出了原始的sub-name，但我希望看到调用时使用的名称。

例子：

use 5.010;
sub x_y_z {
  return ( caller(0) )[3];
}

*foo_bar_baz = \&x_y_z;

say x_y_z();        # x_y_z
say foo_bar_baz();  # x_y_z, but need foo_bar_baz

编辑以解决 XY 问题

我添加了另一个例子来展示我更深层次的意图。我想创建调度表来路由一些任务：

my $dispatch = {
  x => {
    y => {
      z => sub {
          &x_y_z;
      },
    }
  },
  a => {
    b => {
      c => {
        d => sub {
          &a_b_c_d;
        },
      }
    }
  }
}

sub foo {
  my @arg = ( split '_', ( split( '::', ( caller(0) )[3] ) )[1] );  
  return @arg;
}

*x_y_z = \&foo;
*a_b_c_d = \&foo;

如您所想，这棵树可能会长得很大。现在调度树中的许多叶子需要基本相同的子，它们的不同之处只是它们被称为（命名）的方式，我希望只有一个子并为特定任务取别名。

Answer 1

您想要做的事情在 Perl 的数据模型中根本不可能。别名只是一个别名，不是一个有自己身份的对象。

请注意，可以复制一个子程序并给它一个新名称，例如：

use Sub::Name;

*x_y_z = subname x_y_z => \&foo;

但您必须手动执行此操作。

除了堆栈跟踪之外，依赖子名并不是一个好主意。尝试在这些名称之上构建任何逻辑最终可能会导致难以调试的混乱，而不是优雅的软件。

最好将路由名称作为显式参数传递给处理函数，并创建一个辅助函数来抽象必要的管道。例如：

my %routes;

sub route {
  my ($name, $handler) = @_;
  $routes{$name} = sub { $handler->($name => @_) };
  return;
}

sub common_handler { ... }

route a_b_c => \&common_handler;
route x_y_z => \&common_handler;
route foo_bar => sub {
  my ($route) = @_;
  say "Custom handler invoked for route $route";
};

$routes{$name}->(@args);

如果绝对必要，您当然可以实现这样的route 函数，以便将处理程序安装为命名子例程。但此时您正在构建某种框架，例如 Moo(se)，而不是普通的 Perl 模块。

Answer 2

你不能。 foo_bar_baz 是别名。 caller 报告声明的子例程的名称，而不是调用它的名称。请注意，并非所有子例程都有名称，也并非所有调用都是按名称命名的。 （匿名子仅作为 CODE 引用存在；它们在符号表中没有条目。任何子（无论是否命名）都可以通过引用调用。）

也就是说，这里不需要别名。您真正想要的是 sub 应该操作的数据库、表等的额外参数。这样做的惯用方法是包装通用 sub 并通过包装器传递该信息：

my %dispatch = (
    a => { b => { c => sub { foo('a', 'b', 'c', @_) } } },
    x => { y => { z => sub { foo('x', 'y', 'z', @_) } } },
);

$dispatch{a}{b}{c}->('foo');
$dispatch{x}{y}{z}->('bar');

sub foo {
    my $db     = shift;
    my $table  = shift;
    my $task   = shift;
    my @params = @_;
    say "$db $table $task: @params";
}