给定 Perl 中的包名，如何从包中调用子例程？答案

【问题标题】：How do you call a subroutine from a package, given the package name in Perl?给定 Perl 中的包名，如何从包中调用子例程？
【发布时间】：2012-06-05 01:43:38
【问题描述】：

给定一个包含代表包名的字符串的变量，如何调用包的特定子例程？

这是我发现的最接近的东西：

package MyPackage;

sub echo {
    print shift;
}

my $package_name = 'MyPackage';
$package_name->echo('Hello World');

1;

这段代码的问题是子程序被作为类方法调用；包名作为第一个参数传入。我想从包名中调用子例程，而无需隐式传入特殊的第一个参数。

【问题讨论】：

如果你不想传递一个调用者，那么你想要的不是调用一个方法。
@hobbs：谢谢。我已更新问题以使用更正确的术语。

标签： perl reflection methods package

【解决方案1】：

听起来您实际上不想将其作为方法调用，而是作为常规子例程调用。在这种情况下，您可以使用符号引用：

my $package_name = 'MyPackage';
{ 
    no strict 'refs';
    &{ $package_name . '::echo' }( 'Hello World' );
}

【讨论】：

如果你使用$::{$package_name.'::'}{echo}你就不需要使用no strict 'refs';

【解决方案2】：

Perl 方法调用只是常规子例程，它将调用者作为第一个值。

use strict;
use warnings;
use 5.10.1;

{
  package MyPackage;
  sub new{ bless {}, shift } # overly simplistic constructor (DO NOT REUSE)
  sub echo{ say @_ }
}

my $package_name = 'MyPackage';
$package_name->echo;

my $object = $package_name->new();
$object->echo; # effectively the same as MyPackage::echo($object)

MyPackage
MyPackage=HASH(0x1e2a070)

如果您想调用没有调用者的子例程，则需要以不同的方式调用它。

{
  no strict 'refs';
  ${$package_name.'::'}{echo}->('Hello World');
  &{$package_name.'::echo'}('Hello World');
}

# only works for packages without :: in the name
$::{$package_name.'::'}{echo}->('Hello World');

$package_name->can('echo')->('Hello World');

can 方法返回对子例程的引用，如果在调用者上调用该子例程，则该引用将被调用。然后可以单独使用 coderef。
```
my $code_ref = $package_name->can('echo');
$code_ref->('Hello World');
```
使用can有一些注意事项：
- can 可以被包或它继承的任何类覆盖。
- 定义方法的包可能与调用者不同。
不过，这实际上可能是您正在寻找的行为。
另一种方法是使用称为symbolic reference 的东西。
```
{
  no strict 'refs';
  &{ $package_name.'::echo' }('Hello World');
}
```
通常不建议使用符号引用。部分问题在于，可能会在您不打算使用符号引用的地方意外使用符号引用。这就是为什么你不能让use strict 'refs'; 生效。

这可能是做你想做的最简单的方法。

如果您不想使用符号引用，可以使用Stash。

$MyPackage::{echo}->('Hello World');
$::{'MyPackage::'}{echo}->('Hello World');

$main::{'MyPackage::'}{echo}->('Hello World');
$main::{'main::'}{'MyPackage::'}{echo}->('Hello World');
$main::{'main::'}{'main::'}{'main::'}{'MyPackage::'}{echo}->('Hello World');

唯一的问题是您必须将$package_name 拆分为::

*Some::Long::Package::Name::echo = \&MyPackage::echo;

$::{'Some::'}{'Long::'}{'Package::'}{'Name::'}{echo}('Hello World');

sub get_package_stash{
  my $package = shift.'::';
  my @package = split /(?<=::)/, $package;
  my $stash = \%:: ;
  $stash = $stash->{$_} for @package;
  return $stash;
}
get_package_stash('Some::Long::Package::Name')->{echo}('Hello World');

不过，这并不是什么大问题。快速查看CPAN 后，您会发现Package::Stash。

use Package::Stash;
my $stash = Package::Stash->new($package_name);
my $coderef = $stash->get_symbol('&echo');
$coderef->('Hello World');

（Pure Perl 版本的Package::Stash 使用符号引用，而不是 Stash）

甚至可以为子例程/方法创建别名，就好像从使用 Exporter 的模块导入的一样：

*echo = \&{$package_name.'::echo'};
echo('Hello World');

我建议限制别名的范围：

{
  local *echo = \&{$package_name.'::echo'};
  echo('Hello World');
}

这是一个例外，您可以在启用strict 'refs' 的情况下使用符号引用。

【讨论】：

感谢您的全面回答。我接受了它，因为您提供了多种方法来完成我的要求。我特别喜欢“可以”的方法。
@Sam, can 错了。它检查继承树。 can 用于方法。

【解决方案3】：

使用&{ <EXPRESSION> }() 语法调用名称为表达式的子程序，如perldoc perlref 中列出的取消引用运算符所述：

诚然，在这种情况下使用花括号有点傻，但是 BLOCK 可以包含任意表达式，尤其是下标表达式：
  &{ $dispatch{$index} }(1,2,3); # call correct routine

随机实例：

# Note no "use strict"!
use File::Slurp; 
my $p="File::Slurp"; 
@a=&{"${p}::read_file"}(".profile"); 
print $a[0];

【讨论】：