在 Perl 中重新加载模块和重新定义子例程

Question

我目前正在尝试重新加载一个模块。我希望实现的目标是能够更改模块文件中已定义子例程中的某些内容，然后使用新定义重新加载该模块。

目前，我正在将test子例程中的打印语句更改为在等待子例程执行原始代码之后，在重新加载模块之前打印“这是一些不同的文本”。

但是，我目前收到的是消息：
Subroutine test redefined at /Test/testmodule.pm line 9.

这正是我想要的，但是输出如下。

这是一些文字
在 /Test/testmodule.pm 第 9 行重新定义了子程序测试。
这是一些文字

我希望当模块重新加载时，它意识到子程序已被重新定义，下次执行测试子程序时，它将引用新定义而不是旧定义。

我已经搜索过有关重新加载模块的先前问题，但给出的答案是循环依赖项（包 A 使用 B，B 使用 A），或包中的命名空间冲突，但这不是这里的问题.我想要重新定义子例程，并使用新定义。

源代码： main.pl

#!/usr/bin/perl
use strict;
use warnings;
use Module::Reload::Selective;
use Test::testmodule;

while(1) {
    test(); #run module's define subroutine
    sleep(5); #stop terminal from being flooded too quickly

    #Ensure that the module is reloaded
    $Module::Reload::Selective::Options->{SearchProgramDir} = 1;
    $Module::Reload::Selective::Options->{ReloadOnlyIfEnvVarsSet} = 0;
    Module::Reload::Selective->reload(qw(Test::testmodule)); #reload!
}

源代码：testmodule.pm（在./Test/相对于main.pl）

#!/usr/bin/perl
use strict;
use warnings;

# allow exportation
require Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw(test);

sub test {
    print("this is some text\n"); # this line is edited in the source file to
                                  # 'print("this is some different text\n");'
}
1;

任何对教程的指针或引用都会很棒。事实上，如果答案不是非常简单，不直接告诉我答案可以让我阅读您建议的材料并获得更好的整体理解。

所有需要的CPAN模块都已经安装好了，我可以确认testmodule.pm改完后写成功了。

操作系统：Scientific Linux CERN 6，内核版本 2.6.32-131.4.1.el6.x86_64
Perl：v5.10.1 (*) 专为x86_64-linux-thread-multi

非常感谢，
欧文。

Answer 1

我不知道这是否是问题所在，但您在模块中缺少package 语句。这意味着test 是main::test 而不是Test::testmodule::test。

是的，这是 cjm 的答案和我的答案的结合。这段代码对我有用：

在Test/testmodule.pm:

package Test::testmodule;

use strict;
use warnings;

# allow exportation
require Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw(test);

sub test {
    print "this is some text, counter 1\n";
}

1;

在main.pl:

#!/usr/bin/perl
use strict;
use warnings;
use Module::Reload::Selective;
use Test::testmodule;

while(1) {
    test(); #run module's define subroutine

    my $module = do {
        open my $fh, "<", "Test/testmodule.pm"
            or die "could not open the module: $!";

        local $/;
        <$fh>;
    };

    $module =~ s/counter ([0-9])/"counter " . ($1 + 1)/e;

    open my $fh, ">", "Test/testmodule.pm"
        or die "could not open the module: $!";

    print $fh $module;

    close $fh;

    #Ensure that the module is reloaded
    $Module::Reload::Selective::Options->{SearchProgramDir} = 1;
    $Module::Reload::Selective::Options->{ReloadOnlyIfEnvVarsSet} = 0;
    Module::Reload::Selective->reload(qw(Test::testmodule));
    Test::testmodule->import;
} continue {
    sleep 1;
}

澄清一下，当您创建.pm 文件时，Perl 5 不会创建名称空间。当您说package NamespaceName 或您像这样引用该命名空间时，它会创建一个命名空间

sub Test::testmodule::test {
    print "this is some text, counter 1\n";
}

由于您版本中的 test 函数不在 Test::testmodule 命名空间中，因此它从未被重新加载。

Answer 2

您错过了 Module::Reload::Selective 文档的部分内容，其中说重新加载后调用 import。 （虽然它使用间接对象语法，但最好使用标准方法调用。）也就是说，你应该说：

Module::Reload::Selective->reload(qw(Test::testmodule)); #reload!
Test::testmodule->import;                                #reimport!

原因是Exporter 本质上是这样的：

*main::test = \&Test::testmodule::test;

也就是说，main::test 被分配了对Test::testmodule::test 的当前版本的引用。重新加载模块重新定义Test::testmodule::test，但main::test 继续引用原始子。显式调用import 方法会将新版本的sub 复制到main::test。

Answer 3

您可以通过放置来停止发出警告

no warnings 'redefine';

进入加载的模块。

另外请注意，重新加载是一个非常脆弱的概念，它可能会限制您在模块中可以执行的操作。