Delphi：重写的虚拟构造函数后代未被重载调用

Question

我关于 Delphi 构造函数的一系列问题中的另一个问题。

我有一个具有虚拟构造函数的基类：

TComputer = class(TObject)
public
    constructor Create(Teapot: Integer); virtual;
end;

构造函数在有人需要调用的时候是虚拟的

var
   computerClass: class of TComputer;
   computer: TComputer;
begin     
   computer := computerClass.Create(nTeapot);

构造函数在后代中是overridden：

TCellPhone = class(TComputer) 
public
   constructor Create(Teapot: Integer); override;
end;

TiPhone = class(TCellPhone ) 
public
   constructor Create(Teapot: Integer); override;
end;

TCellPhone 和 TiPhone 的后代每个都有机会进行自己的初始化（为了便于阅读，不包括成员）。

但是现在我向某个祖先添加了一个重载的构造函数：

TCellPhone = class(TComputer) 
public
   constructor Create(Teapot: Integer); override; overload;
   constructor Create(Teapot: Integer; Handle: string); overload;
end;

TCellPhone 中的备用构造函数调用另一个 virtual 构造函数，因此它始终获得正确的覆盖行为：

constructor TCellPhone.Create(Teapot: Integer; Handle: string);
begin
   TCellPhone.Create(Teapot); //call sibling virtual constructor

   FHandle := Handle;
end;

问题是从不调用后代的、被覆盖的构造函数。调用的实际堆栈跟踪链是：

phone := TiPhone.Create(37, 'spout')
   constructor TCellPhone.Create(Teapot: Integer; Handle: string)
      constructor TCellPhone.Create(Teapot: Integer)
         constructor TComputer.Create(Teapot: Integer)
            TObject.Create

对TCellPhone.Create(int) 的同级调用，它是虚拟的，应该调用TiPhone 中的后代、被覆盖的方法：

phone := TiPhone.Create(37, 'spout')
   constructor TCellPhone.Create(Teapot: Integer; Handle: string)
      constructor TiPhone.Create(Teapot: Integer)
         constructor TCellPhone.Create(Teapot: Integer)
            constructor TComputer.Create(Teapot: Integer)
               TObject.Create

所以似乎 Delphi 尝试使用同级虚拟构造函数并没有按预期工作。

那么一个构造函数使用另一个构造函数是不是一个坏主意？重载构造函数中的代码是彼此复制粘贴版本的设计意图吗？

我注意到在 .NET 中一些构造函数相互链接：

public Bitmap(int width, int height) : this(width, height, PixelFormat.Format32bppArgb) {}

public Bitmap(int width, int height, PixelFormat format) {...}

这似乎只是一个问题，如果：

• 构造函数是虚拟的
• 你重载了构造函数

你不能让一个构造函数重载另一个的规则吗？

Answer 1

错误..

constructor TCellPhone.Create(Teapot: Integer; Handle: string);
begin
   TCellPhone.Create(Teapot); //call sibling virtual constructor

   FHandle := Handle;
end;

应该是：

constructor TCellPhone.Create(Teapot: Integer; Handle: string);
begin
   Create(Teapot); //call sibling virtual constructor

   FHandle := Handle;
end;

您只是创建了一个新的 TCellphone 实例，而不是调用另一个 Create 方法。