Qt : button click => haskell程序中应该出现一条消息

Question

我尝试使用haskell和Qt在ubuntu上使用sublime text 3创建一个单击按钮时显示文本的程序。 但显然在定义信号键时存在问题（该键将识别单击按钮时调用的信号）。 此外，很难找到有关 HsQML 的文档，即连接 haskell 和 Qt 的绑定。

代码：

module Main where

import Graphics.QML
import Control.Concurrent
import Control.Exception
import Data.IORef
import Data.Text (Text)
import qualified Data.Text as T

    main :: IO ()
    main = do
        state <- newIORef $ T.pack ""
        skey <- newSignalKey
        clazz <- newClass [
            defPropertySigRO' "my_label" skey (\_ -> readIORef state),
            defMethod' "sayHello" (\obj txt -> do
                writeIORef state txt
                fireSignal skey obj
                return ())]
        ctx <- newObject clazz ()
        runEngineLoop defaultEngineConfig {
            initialDocument = fileDocument "exemple2.qml",
            contextObject = Just $ anyObjRef ctx}

错误信息：

Build FAILED

/home/lowley/Documents/haskell/Qt/exemple-2.hs: line 13, column 10:
  No instance for (SignalSuffix (IO a0))
    arising from a use of `newSignalKey'
  The type variable `a0' is ambiguous
  Possible fix: add a type signature that fixes these type variable(s)
  Note: there is a potential instance available:
    instance SignalSuffix (IO ()) -- Defined in `Graphics.QML.Objects'
  Possible fix:
    add an instance declaration for (SignalSuffix (IO a0))
  In a stmt of a 'do' block: skey <- newSignalKey
  In the expression:
    do { state <- newIORef $ T.pack "";
         skey <- newSignalKey;
         clazz <- newClass
                    [defPropertySigRO' "my_label" skey (\ _ -> readIORef state),
                     defMethod' "sayHello" (\ obj txt -> ...)];
         ctx <- newObject clazz ();
         .... }
  In an equation for `main':
      main
        = do { state <- newIORef $ T.pack "";
               skey <- newSignalKey;
               clazz <- newClass
                          [defPropertySigRO' "my_label" skey (\ _ -> ...), ....];
               .... }

已解决！ 但是我想知道为什么这个程序可以编译没有上面的错误：

module Main where

import Graphics.QML
import Control.Concurrent
import Control.Exception
import Data.IORef
import qualified Data.Text as T

main :: IO ()
main = do
    state <- newIORef $ T.pack ""
    skey <- newSignalKey
    clazz <- newClass [
        defPropertySigRO' "result" skey (\_ ->
            readIORef state),
        defMethod' "factorial" (\obj txt -> do
            let n = read $ T.unpack txt :: Integer
            writeIORef state $ T.pack "Working..."
            fireSignal skey obj
            forkIO $ do
                let out = T.take 1000 . T.pack . show $ product [1..n]
                evaluate out
                writeIORef state out
                fireSignal skey obj
            return ())]
    ctx <- newObject clazz ()
    runEngineLoop defaultEngineConfig {
        initialDocument = fileDocument "factorial2.qml",
        contextObject = Just $ anyObjRef ctx}

Answer 1

有错误告诉您 GHC 不知道 newSignalKey 创建的信号应该具有什么类型（newSignalKey :: SignalSuffix p => IO (SignalKey p)。GHC 不知道 p 应该是什么，因为您没有指定它）。像这样添加显式类型签名：

skey <- newSignalKey :: IO (SignalKey (IO ()))

应该修复您看到的错误。

好的，那么为什么它在第二个示例中有效？要理解这一点，我们必须看看 GHC 知道什么以及它可以确定 skey 的类型。

在第一个示例和第二个示例中，skey 的用法如下：

do
  ...
  fireSignal skey obj
  ...

因为fireSignal :: SignalKey p -> ObjRef () -> p（简化类型，fireSignal 的完整类型更通用），GHC 知道p 必须是IO something，因为它用于预期IO something 操作的上下文中（作为 IO 中的 do 块的一部分）。它不知道something 是什么，因为从未使用过IO 操作的返回值。所以留下skey :: SignalKey (IO something)，正确报错something不明确（不知道something应该是什么类型）。

在第二个示例中，skey 也用于以下模式：

forkIO $ do
  ...
  fireSignal skey obj

由于forkIO 需要一个返回() 类型值的IO 操作，GHC 现在知道fireSignal skey obj :: IO ()（所以在这种情况下，它知道something 必须是()）。这意味着p 不再有歧义，它必须是IO ()。