Delphi中如何知道类型变量是DateTime、Date和Time

Question

我需要知道类型变量 TDateTime、TDate 和 TTime。

有人知道怎么做吗？

我用下面的代码，结果是“Is NOT TDateTime”，“Is NOT TDate”，“Is NOT Ttime”

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.Rtti,
  System.SysUtils;

var
  DateTime, Date,Time: TValue;

begin

  DateTime:= StrToDateTime( '01/01/2013 01:05:09' );
  if ( DateTime.TypeInfo = System.TypeInfo(TDateTime) ) then
    Writeln( 'Is TDateTime' )
  else
    Writeln( 'Is NOT TDateTime' );

  Date:=  StrToDate( '01/01/2015' );
  if ( Date.TypeInfo = System.TypeInfo(TDate) ) then
    Writeln( 'Is TDate' )
  else
    Writeln( 'Is NOT TDate' );

 Time:=  StrToTime( '01:01:02' );
  if ( Date.TypeInfo = System.TypeInfo(TTime) ) then
    Writeln( 'Is TTime' )
  else
    Writeln( 'Is NOT TTime' );

 Readln;

end.

谢谢

Answer 1

TValue 的 Implicit 运算符重载得到了你。

当您将StrToDateTime、StrToDate 和StrToTime 的结果分配给TValue 时，它使用TValue 中最匹配的Implicit 运算符重载，即Extended。

另外请记住，所有三个函数都返回 TDateTime，因此即使 TDateTime、TDate 和 TTime 存在运算符重载，它也不会按预期工作。

要获得正确的结果，您必须在将值分配给 TValue 变量时明确指定类型：

DateTime := TValue.From<TDateTime>(StrToDateTime( '01.01.2013 01:05:09' ));

Date:= TValue.From<TDate>(StrToDate( '01.01.2015' ));

Time:= TValue.From<TTime>(StrToTime( '01:01:02' ));

Answer 2

以防万一您试图确定 StrToDateTime 的结果类型：

type
  TDateType = (dtDate, dtDateTime, dtTime);

function getDateType(date: TDateTime): TDateType;
begin
  if Trunc(date) = date then // Or DateOf(date), if available
  begin
    Result := dtDate;
  end
  else
  begin
    if Trunc(date) = 0 then // Or DateOf(date), if avaialble
    begin
      Result := dtTime
    end
    else
    begin
      Result := dtDateTime;
    end;
  end;
end;

// Sample
var
  result: TDateType;
begin
  result := getDateType(StrToDateTime('01/01/2013 01:05:09')); // dtDateTime
  result := getDateType(StrToDateTime('01/01/2015')); // dtDate
  result := getDateType(StrToDateTime('01:01:02')); // dtTime
  // One caveat
  result := getDateType(StrToDateTime('01/01/2013 00:00:00')); // dtDate
end;

或者，您可以使用TryStrToDate、TryStrToTime 和TryStrToDateTime 函数。

Answer 3

如果您好奇，TDateTime 在内部被编码为浮点 Double。

TDateTime 内部结构
小数部分表示时间，整数部分表示日期。
知道这一点后，以下测试将评估为true。

dtTime: ABS(Double(DateTime1)) < 1.0 
dtDate: Trunc(Double(DateTime1)) = Double(DateTime1)
dtDateTime:  (     (ABS(Double(DateTime1)) > 1.0) 
         and (Trunc(Double(DateTime1)) <> Double(DateTime1)) )

显然，这是一种非常迂回的测试方式，但有时它有助于了解 TDateTime 在内部是如何形成的。

DateUtils
这些测试的合理版本是：

uses DateUtils;

dtDate: DateTime1 = DateOf(DateTime1)
dtTime: DateTime1 = TimeOf(DateTime1)
dtDateTime:(DateTime1 <> DateOf(DateTime1)) and (DateTime1 <> TimeOf(DateTime1))

TDateTime 与 Excel 兼容
值0 链接到 Microsoft Excel 中的时代：1899 年 12 月 30 日； 12:00 A.M.
^{（应该是 1-1-1900，但他们更改了它以弥补 Lotus 123 日期算法中的错误）}
这很好，因为 Delphi 的 TDateTime 与 Excel 的 DateTime 完全兼容。

这是官方文档：http://docwiki.embarcadero.com/Libraries/XE5//en/System.TDateTime