xslt 和 xpath：匹配前面的注释

Question

给定这个 xml：

<root>
    <list>
        <!-- foo's comment -->
        <item name="foo" />
        <item name="bar" />
        <!-- another foo's comment -->
        <item name="another foo" />
    </list>
</root>

我想使用 XPath 来选择所有前面有评论的项目节点，也就是说，我想选择“foo”和“another foo”项目，而不是“bar”项目。

我已经摆弄了前兄弟轴和 comment() 函数，但无济于事。

Answer 1

这似乎有效：

//comment()/following-sibling::*[1]/self::item

它寻找紧跟在 cmets 之后的兄弟姐妹，这些兄弟姐妹也是 <item> 元素。我不知道有更好的方式来表达::*[1]/self::item 部分，这很难看；请注意，如果它写成::item[1]，那么它也会发现<item>s 不是立即由评论处理的。

Answer 2

当前选择的解决方案：

//comment()/following-sibling::*[1]/self::item

在注释和元素之间存在处理指令（或整组处理指令）的情况下不起作用 - 正如 Martin Honnen 的评论所指出的那样。

下面的解决方案没有这样的问题。

以下 XPath 表达式仅选择紧跟在注释节点之前的元素节点，或者紧跟在仅空白文本节点之前的元素节点，该文本节点紧跟在评论节点之前：

(//comment()
   /following-sibling::node()
     [1]
     [self::text()
    and 
     not(normalize-space())
     ]
      /following-sibling::node()
             [1] [self::item]
 ) 
|
(//comment()
   /following-sibling::node()
     [1]
     [self::item]
 ) 

这是一个完整的测试：

我们使用这个 XML 文档：

<root>
    <list>
        <!-- foo's comment -->
        <item name="foo" />
        <item name="bar" />
        <!-- another foo's comment -->
        <item name="another foo" />
        <!-- comment 3 --><item name="immed.after 3"/>
        <!-- comment 4 --><?PI ?><item name="after PI"/>
    </list>
</root>

当对上述 XML 文档应用以下转换时：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>


 <xsl:template match="/">
   <xsl:copy-of select=
    "
    (//comment()
       /following-sibling::node()
         [1]
         [self::text()
        and
         not(normalize-space())
         ]
          /following-sibling::node()
                 [1] [self::item]
     )
    |
    (//comment()
       /following-sibling::node()
         [1]
         [self::item]
     )
    "/>
 </xsl:template>
</xsl:stylesheet>

产生想要的正确结果：

<item name="foo"/>
<item name="another foo"/>
<item name="immed.after 3"/>

Answer 3

如this thread 中所述，引入一个测试（<xsl:if test="..."></xsl:if>），如：

preceding-sibling::comment()

只会测试节点是否有前面的兄弟节点是评论。

如果你想知道，在前面的兄弟元素或 cmets 中，最近的一个是否是注释，你可以尝试：

(preceding-sibling::*|preceding-sibling::comment())[1][self::comment()] # WRONG

但是：这是行不通的，因为虽然“[1]”意味着首先是向后的方向 对于preceding-sibling，这并不意味着对于带括号的表达式 - 它 表示文档顺序中的第一个

你可以试试：

(preceding-sibling::*|preceding-sibling::comment())[last()][self::comment()]

或

preceding-sibling::node()[self::*|self::comment()][1][self::comment()]

---

例如：

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
  <xsl:output omit-xml-declaration="no" indent="no"/>

  <xsl:template match="//item">
    <xsl:if test="preceding-sibling::node()[self::*|self::comment()][1][self::comment()]">
      <xsl:value-of select="./@name" />
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

只会显示：

foo
another foo

打字时：

C:\Prog\xslt\preceding-sibling_comment>
  java -cp ..\saxonhe9-2-0-6j\saxon9he.jar net.sf.saxon.Transform -s:test.xml -xsl:t.xslt -o:res.xml

与：

• test.xml：您的文件显示在您的问题中
• t.xslt：上面的xslt文件
• res.xml：生成的转换文件

---

编辑：因为它没有考虑处理指令，所以我将该答案保留为 Community Wiki。