Haskell：随机数

Question

我写了一个函数来随机从 [-10,10] 中获取一对。

import System.Random


main = 
    do { 
         s <- randomNumber
       ; b <- randomNumber
       ; print (head s,head b)}
randomNumber :: IO [Int]
randomNumber = sequence $ replicate 1 $ randomRIO (-10,10)

现在我想取一个像 [(1,2),(2,3),(2,3)] 这样的列表，所有的数字都来自 randomNumber。我怎样才能做到这一点？我不知道如何实现。

我尝试使用状态来获得随机性，但不知何故我无法在我的计算机上使用状态。 我这样做了：

import System.Random
import Control.Monad.State
randomSt :: (RandomGen g, Random a) => State g a
randomSt = State random

但是当我编译它时，它显示：不在范围内：数据构造函数'State'

Answer 1

如果你想要的只是一个函数

  randomPairs :: IO [(Int, Int)]

然后我们可以做类似的事情

   randomList :: IO [Int]
   randomList = randomRs (-10, 10) `fmap` newStdGen
   randomPairs = ??? randomList randomList

其中??? 需要两个IO [Int] 并将它们“压缩”在一起以形成IO [(Int, Int)]。我们现在转向hoogle 并查询函数[a] -> [a] -> [(a, a])，我们找到了一个函数zip :: [a] -> [b] -> [(a, b)]，我们现在只需要将zip“提升”到IO monad 以便在IO 列表中使用它，所以我们最终得到了

  randomPairs = liftM2 zip randomList randomList

或者如果我们想要真正花哨，我们可以使用 applicatives 来代替

  import Control.Applicative

  randomPairs = zip <$> randomList <*> randomList

但是从您的randomNumber 功能来看，您真的只想要一个 对。这个想法非常相似。我们没有生成一个列表，而是只生成一个带有randomRIO (-10, 10) 的随机数并提升(,) :: a -> b -> (a, b) 导致

  randomPair = (,) <$> randomRIO (-10, 10) <*> randomRIO (-10, 10)

最后，State 数据构造函数不久前消失了，因为 MTL 从具有单独的 State 和 StateT 类型转变为使 State 成为类型同义词。现在你需要使用小写的state :: (s -> (s, a)) -> State s a

澄清一下，我的最终代码是

import System.Random
import Control.Monad

randomList :: IO [Int]
randomList = randomRs (-10, 10) `fmap` newStdGen

pairs :: IO [(Int, Int)]
pairs = liftM2 zip randomList randomList

somePairs n = take n `fmap` pairs

main = somePairs 10 >>= print