存储过程中的 TSQL 互斥访问

Question

多个网络服务器访问 SQL Server 以获取数字代码，当此代码不存在时，它必须由 SQL Server 自动生成。

我需要确保即使有两个并发调用进来并且代码不存在，也只会创建一个代码并且两个调用都返回相同的代码。所以我必须这样做：

begin lock
  if code exists
    return code
  else
    generate code
    return code
end lock

我一直在阅读有关隔离级别和表锁定的一些内容，但我对所有这些都感到非常混乱。首先我认为 SERIALIZABLE 隔离级别是我需要的，但显然不是。

那么，您将如何在 TSQL 中完成“锁定”？

非常感谢。

更新：

当我尝试使用this 设置可序列化级别时遇到此错误：

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER PROCEDURE get_code 
AS
BEGIN
    SET TRANSACTION ISOLATION LEVEL SERIALIZABLE
    GO
    BEGIN TRANSACTION

    select code from codes where granted is null;
END
GO

消息 1018，级别 15，状态 1，程序 get_code，第 4 行附近的语法不正确 “可序列化”。如果这是为了 表提示的一部分，一个 WITH 关键字 现在需要括号。看 SQL Server 联机丛书 句法。消息 102，级别 15，状态 1， 第 5 行 'END' 附近的语法不正确。

什么意思？

Answer 1

SERIALIZABLE 是锁定的隔离级别，而不是semaphore。

在这种情况下它不会起作用，你要做的就是在 TXN 的末尾保持一个读锁，这不会阻止另一个进程读取代码。

您需要在事务模式下使用sp_getapplock。您可以将其配置为等待、立即轰炸等：由您决定

这是基于我来自Nested stored procedures containing TRY CATCH ROLLBACK pattern?的模板

ALTER PROCEDURE get_code 
AS
SET XACT_ABORT, NOCOUNT ON

DECLARE @starttrancount int, @result int;

BEGIN TRY
    SELECT @starttrancount = @@TRANCOUNT

    IF @starttrancount = 0 BEGIN TRANSACTION

    EXEC @result = sp_getapplock 'get_code', 'Exclusive', 'Transaction', 0 
    IF @result < 0
        RAISERROR('INFO: One at a time please`!', 16, 1);

    [...Perform work...]


    IF @starttrancount = 0 
        COMMIT TRANSACTION
    ELSE
        EXEC sp_releaseapplock 'get_code';
END TRY
BEGIN CATCH
    IF XACT_STATE() <> 0 AND @starttrancount = 0 
        ROLLBACK TRANSACTION
    RAISERROR [rethrow caught error using @ErrorNumber, @ErrorMessage, etc]
END CATCH
GO

Answer 2

我就是这样做的。给定一个表MetaInfo，列MetaKey varchar(max) and MeatValueLong bigInt。

注意，在我的例子中，我们的目标是在没有重复的情况下专门获得增加的价值。我使用行锁在这个单一操作上创建隔离。 （是的，我知道我可以使用插入和自动增量键，但还有一个附加要求，即调用者可以传入最小值。）

CREATE PROCEDURE [dbo].[uspGetNextID]
(
  @inID bigInt 
)
AS
BEGIN
    SET NOCOUNT ON;

    BEGIN TRANSACTION

    -- This section can be removed if you want to pass in an id.
    SET @inID = 0

    UPDATE MetaInfo WITH (ROWLOCK) 
      SET MetaValueLong = CASE 
                            WHEN ISNULL(MetaValueLong,0) > @inID THEN MetaValueLong+1 
                            ELSE @inID+1
                          END 
    WHERE MetaKey = 'Internal-ID-Last'

    SELECT MetaValueLong 
    FROM MetaInfo
    WHERE MetaKey = 'Internal-ID-Last'

    COMMIT TRANSACTION 

END

Answer 3

是的，SET ISOLATION LEVEL SERIALIZABLE 正是您所需要的。它不允许脏写和脏读。可序列化事务中的所有 db-objets 都被锁定，因此其他连接只有在第一个提交或回滚时才能读取/写入。