在活动模式中使用 typeof<_>

Question

给定以下人为的主动模式：

let (|TypeDef|_|) (typeDef:Type) (value:obj) =
  if obj.ReferenceEquals(value, null) then None
  else
    let typ = value.GetType()
    if typ.IsGenericType && typ.GetGenericTypeDefinition() = typeDef then Some(typ.GetGenericArguments())
    else None

以下内容：

let dict = System.Collections.Generic.Dictionary<string,obj>()
match dict with
| TypeDef typedefof<Dictionary<_,_>> typeArgs -> printfn "%A" typeArgs
| _ -> ()

给出错误：

模式匹配中的意外类型应用。应为“->”或其他标记。

但这有效：

let typ = typedefof<Dictionary<_,_>>
match dict with
| TypeDef typ typeArgs -> printfn "%A" typeArgs
| _ -> ()

为什么这里不允许typedefof（或typeof）？

Answer 1

即使您使用参数化的活动模式（其中参数是某个表达式），编译器也会将参数解析为模式（而不是表达式），因此语法受到更多限制。

我认为这与此处讨论的问题基本相同：How can I pass complex expression to parametrized active pattern?（我不确定实际的编译器实现，但 F# 规范说它应该解析为一种模式）。

作为一种解决方法，您可以在引号内编写任何表达式，因此您可以这样做：

let undef<'T> : 'T = Unchecked.defaultof<_>

let (|TypeDef|) (typeExpr:Expr) (value:obj) =
  let typeDef = typeExpr.Type.GetGenericTypeDefinition()
  // ...

let dict = System.Collections.Generic.Dictionary<string,obj>()
match dict with
| TypeDef <@ undef<Dictionary<_,_>> @> typeArgs -> printfn "%A" typeArgs
| _ -> ()

Answer 2

除了 Tomas 的回答之外，在这种情况下，麻烦的语法似乎与显式类型参数有关。另一种解决方法是使用虚拟参数来传输类型信息

let (|TypeDef|_|) (_:'a) (value:obj) =
  let typeDef = typedefof<'a>
  if obj.ReferenceEquals(value, null) then None
  else
    let typ = value.GetType()
    if typ.IsGenericType && typ.GetGenericTypeDefinition() = typeDef then Some(typ.GetGenericArguments())
    else None

let z = 
    let dict = System.Collections.Generic.Dictionary<string,obj>()
    match dict with
    | TypeDef (null:Dictionary<_,_>) typeArgs -> printfn "%A" typeArgs
    | _ -> ()