使用不完整的模式匹配作为过滤器？

Question

假设我有以下代码：

type Vehicle =
| Car  of string * int
| Bike of string

let xs = [ Car("family", 8); Bike("racing"); Car("sports", 2); Bike("chopper") ]

我可以在命令式 for 循环中使用不完整的模式匹配过滤上面的列表，例如：

> for Car(kind, _) in xs do
>    printfn "found %s" kind;;

found family
found sports
val it : unit = ()

但会导致：warning FS0025: Incomplete pattern matches on this expression. For example, the value 'Bike (_)' may indicate a case not covered by the pattern(s). Unmatched elements will be ignored.

由于我的意图是忽略不匹配的元素，有没有可能摆脱这个警告？

有没有一种方法可以在不导致 MatchFailureException 的情况下使用列表理解？例如类似的东西：

> [for Car(_, seats) in xs -> seats] |> List.sum;;
val it : int = 10

Answer 1

两年前，您的代码是有效的，并且是执行此操作的标准方式。然后，语言已被清理，设计决定是支持显式语法。因此，我认为忽略该警告并不是一个好主意。

您的代码的标准替换是：

for x in xs do
    match x with
    | Car(kind, _) -> printfn "found %s" kind
    | _ -> ()

（您也可以使用 pad 示例中的高阶函数）

对于另一个，List.sumBy 很合适：

xs |> List.sumBy (function Car(_, seats) -> seats | _ -> 0)

如果您更喜欢使用推导式，这是显式语法：

[for x in xs do
    match x with
    | Car(_, seats) -> yield seats
    | _ -> ()
] |> List.sum

Answer 2

您可以通过#nowarn 指令或--nowarn: 编译器选项使任何警告静音（传递警告编号，此处为25，如FS0025）。

但更一般地说，不，最好的办法是显式过滤，就像在另一个答案中一样（例如使用choose）。

Answer 3

要明确声明要忽略不匹配的情况，可以使用List.choose 并为那些不匹配的元素返回None。您的代码可以以更惯用的方式编写如下：

let _ = xs |> List.choose (function | Car(kind, _) -> Some kind
                                    | _ -> None)
           |> List.iter (printfn "found %s")

let sum = xs |> List.choose (function | Car(_, seats)-> Some seats
                                      | _ -> None) 
             |> List.sum