仅对 Flex/Bison 使用字符串

Question

我是 Flex/Bison 的新手。我只想对值使用字符串（是语言翻译器）。我有这个供测试：

example.l:

%option noyywrap nodefault

%{
#include <string.h>
#include "example.tab.h"
%}

%%

[ \t\n] {;}
"<="    {return LEFT;}
"=>"    {return RIGHT;}
[0-9]+ { yylval=strdup(yytext); return NUMBER; }
. { return yytext[0]; }

%%

example.y：

%{
#include <stdio.h>
#define YYSTYPE char const *
%}

%token NUMBER
%token LEFT "<=" RIGHT "=>"

%%

start: %empty | start tokens

tokens:
       NUMBER "<=" NUMBER { printf("%s <= %s\n",$1,$3); }
     | NUMBER "=>" NUMBER { printf("%s => %s\n",$1,$3); }
     | NUMBER '>' NUMBER  { printf("%s > %s\n",$1,$3); }
     | NUMBER '<' NUMBER  { printf("%s < %s\n",$1,$3); }

%%

main(int argc, char **argv) { yyparse(); }
yyerror(char *s) { fprintf(stderr, "error: %s\n", s); }

当我编译时：

bison -d example.y
flex example.l
cc -o example example.tab.c lex.yy.c -lfl
example.l: In function ‘yylex’:
example.l:13:9: warning: assignment makes integer from pointer without a cast
 [0-9]+ { yylval=strdup(yytext); return NUMBER; }
         ^

但按预期工作。

如果我不使用 #define YYSTYPE char const * 而使用 %union:

%union {
   char * txt;
}

%token <txt> NUMBER

并将分配更改为[0-9]+ { yylval.txt=strdup(yytext); return NUMBER; }，它没有警告并且可以工作。

我尝试过在 flex 文件中定义相同的 YYSTYPE 并进行分配但没有成功。怎么了？如何在不使用 %union 的情况下修复？

谢谢。

Answer 1

您需要在#include "example.tab.h" 之前将#define YYSTYPE char const * 移动到example.l。

如果您查看 example.tab.h 内部，您会发现如下内容：

#if ! defined YYSTYPE && ! defined YYSTYPE_IS_DECLARED
typedef int YYSTYPE;
// ...
#endif

我的意思是您需要在此代码之前定义 YYSTYPE，即在 #include "example.tab.h 之前。否则，如果此时未定义 YYSTYPE，则 YYSTYPE 将被定义为 int。

另一种可能性是使用野牛功能%define api.value.type {char const *}，您需要将其放入example.y。在这种情况下，example.tab.h 将使用 char const * 类型的 YYSTYPE 生成。

Answer 2

最后的工作示例是：

example.l:

%option noyywrap nodefault

%{
#include <string.h>
#define YYSTYPE char *
#include "example.tab.h"
%}

%%

[ \t\n] {;}
"<="    {return LEFT;}
"=>"    {return RIGHT;}
[0-9]+ { yylval=strdup(yytext); return NUMBER; }
. { return yytext[0]; }

%%

example.y：

%{
#include <stdio.h>
#define YYSTYPE char *
%}

%token NUMBER
%token LEFT "<=" RIGHT "=>"

%%

start: %empty | start tokens

tokens:
       NUMBER "<=" NUMBER { 
          printf("%s <= %s\n",$1,$3);
          free($1);
          free($3);
       }
     | NUMBER "=>" NUMBER {
          printf("%s => %s\n",$1,$3);
          free($1);
          free($3);
       }
     | NUMBER '>' NUMBER  {
          printf("%s > %s\n",$1,$3);
          free($1);
          free($3);
       }
     | NUMBER '<' NUMBER  {
          printf("%s < %s\n",$1,$3);
          free($1);
          free($3);
       }

%%

main(int argc, char **argv) { yyparse(); }
yyerror(char *s) { fprintf(stderr, "error: %s\n", s); }