使用 cmake 找不到共享库的 API 头文件

Question

我正在一个项目中构建一个共享库并在另一个项目中使用它。它们共享一个前缀，但我没有将它们构建在一起（例如，<prefix>/mylib 和 <prefix>/myproject）。 mylib 和 myproject 都有 src 和 include 目录。

共享库的CMakeList.txt：

cmake_minimum_required(VERSION 3.5)
project(mylib)

add_library(mylib SHARED
            src/mylib.c
            )

target_include_directories(mylib PRIVATE include)

set_target_properties(mylib PROPERTIES PUBLIC_HEADER include/mylib.h)

install(TARGETS
  mylib
  LIBRARY DESTINATION lib
  PUBLIC_HEADER DESTINATION include
  RUNTIME DESTINATION bin)

这导致mylib.so 安装在install/mylib/lib/mylib.so 中，mylib.h 安装在install/mylib/include/mylib.h 中，这正是我的意图。

然后我想构建一个使用mylib的项目：

#include "mylib.h"

int main(void)
{
    // use some functions in mylib
}

main.c 的关联 CMakeList.txt 文件：

cmake_minimum_required(VERSION 3.5)
project(myproject)

find_package(mylib REQUIRED)

add_executable(myproject src/main.c)
target_link_libraries(myproject mylib)

install(TARGETS
  myproject
  DESTINATION lib/${PROJECT_NAME})

这会产生：

main.c: fatal error: mylib.h: No such file or directory
#include "mylib.h"
         ^~~~~~~~~

如果我将 CMakeList.txt 更改为包含以下内容：

find_path(MYLIB_INCLUDE_DIR mylib.h)
...
target_include_directories(myproject PUBLIC ${MYLIB_INCLUDE_DIR})

然后它找到标题，但没有找到库。我收到链接器错误：

/usr/bin/ld: cannot find -lmylib

如果我将 CMakeList.txt 更改为包含以下内容：

find_library(MYLIB_LIB mylib)
...
target_link_libraries(myproject ${MYLIB_LIB})

然后构建。

我（想我）理解为什么手动查找库和包含文件是可行的，但这似乎是错误的处理方式......

find_package(mylib) 似乎确实找到了mylib 包（我可以打印cmake 缓存变量和mylib_FOUND=1），但没有找到使用myproject 构建的库和标头。

Answer 1

您需要在库项目的target_include_directories 中为“构建”和“安装”变体指定包含目录：

target_include_directories(mylib PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include> # build variant
    $<INSTALL_INTERFACE:include> # install variant
)

顺便说一句，target_include_directories 命令的文档中提供了此类示例。

另外，安装时需要EXPORT库：

install(
  TARGETS mylib
  EXPORT mylib
  LIBRARY DESTINATION lib
  PUBLIC_HEADER DESTINATION include
  RUNTIME DESTINATION bin)

有关使用 cmake 导出库的教程，请参阅 this answer。