如何在 CMake 中使用动态链接库？

Question

我有一个简单的程序如下：

CMakeLists.txt：

cmake_minimum_required(VERSION 3.5)

project(test LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

LINK_DIRECTORIES(${PROJECT_SOURCE_DIR})

add_executable(test main.cpp)
target_include_directories(test PRIVATE ${PROJECT_SOURCE_DIR})    
target_link_libraries(test PRIVATE power.dll)

main.cpp:

#include <iostream>
#include "power.h"

using namespace std;

int main()
{
    cout << "Hello World!" << endl;
    power(4.);
    return 0;
}

power.h:

#ifndef POWER_H
#define POWER_H

double power(double number) noexcept;

#endif // POWER_H

power.h 的实现位于名为 power.dll 的 .dll 中。 如果我用 MinGW 7.3.0 X64 编译这个项目说：

error: undefined reference to `power(double)'

如果我用 MSVC 2017 X64 编译它说：

error: LNK1104: cannot open file 'power.lib'

这两个错误都表明链接器无法检测到power.dll。 我做了很多搜索，但没有一个解决方案对我有用！ 有人可以帮忙吗？ 提前致谢！

Answer 1

您对动态库的建模不正确，无论是在 CMake 还是在源代码级别。

作为起点，尝试将 dll 构建为与消费可执行文件相同的 CMake 项目的一部分：

cmake_minimum_required(VERSION 3.5)

project(test LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

include(GenerateExportHeader)
add_library(power SHARED power_sources.cpp power.h)
generate_export_header(power)
target_include_directories(power PUBLIC ${PROJECT_BINARY_DIR} ${PROJECT_SOURCE_DIR})

add_executable(test main.cpp)
target_link_libraries(test PRIVATE power)

注意generate_export_header 函数的使用，它指示 CMake 生成宏，以便以可移植的方式在共享库接口上导出函数。由于生成的文件进入二进制目录树，我们必须相应地调整库的包含目录。

为确保函数正确导出，请按如下方式更改标题：

#ifndef POWER_H
#define POWER_H

#include <power_export.h>

POWER_EXPORT double power(double number) noexcept;

#endif // POWER_H

请注意，generare_export_header 允许您广泛自定义生成的导出标头。

确保您从该基线构建和运行项目。

如果您想在外部构建 dll（这不是绝对必要的，但因为这是您的问题...），我们必须将 CMake 文件修改为：

cmake_minimum_required(VERSION 3.5)

project(test LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

find_package(power)

add_executable(test main.cpp)
target_link_libraries(test PRIVATE power)

所有的魔法都发生在find_package 电话中。该调用现在负责提供以前由构建库的行处理的所有信息：

• 提供导入的目标 power 以供 target_link_libraries 调用使用
• 通过导入目标关联导入库（power.lib 文件）的库名
• 公开的目录包括两个 power.h 和 power_export.h 通过导入的目标

您可以在查找脚本中手动构建此类导入的目标，也可以让 CMake 为您完成。在第一种情况下，创建一个FindPower.cmake 脚本文件，确保它的位置是CMAKE_MODULE_PATH 的一部分，并编写用于查找库和头文件并在其中构建导入目标的代码。请注意，以可移植的方式做到这一点可能非常棘手，并且远远超出了 StackOverflow 问题的范围。在第二种情况下，让构建 power 库的 CMake 脚本执行安装步骤，在此期间将生成 a config file package，然后您的 test 项目可以使用它。请注意，如果 power 库本身不是使用 CMake 构建的，则此方法不可行，因此在这种情况下，您必须坚持使用第一个选项。

Answer 2

Windows 中的动态链接要求使用关键字__declspec 声明外部可见符号。你的头文件“power.h”应该被修改：

#ifndef POWER_H
#define POWER_H

#if defined(__WIN32__) && !defined(__CYGWIN__)
#  if (defined(_MSC_VER) || defined(__MINGW32__)) && defined(BUILD_DLL)
#    define POWERAPI __declspec(dllexport)
#  elif (defined(_MSC_VER) || defined(__MINGW32__))
#    define POWERAPI __declspec(dllimport)
#  endif
#endif

POWERAPI double power(double number) noexcept;

#endif // POWER_H

在使用CMake构建DLL power.dll的项目中，你应该define the symbolBUILD_DLL:

add_definitions(-DBUILD_DLL)

那么它应该在 MSVC 编译器时生成一个 power.lib 文件，在使用 MINGW 时生成一个 power.a 文件。不要在使用 DLL 的项目中定义 BUILD_DLL，它应该可以工作。