cmake不会在自定义命令中复制文件

Question

我想将 qml 文件从源目录复制到构建目录。以下脚本仅在第一次时才能正常工作。当我更改任何 *.qml 文件并运行 make 时，它​​们不会被复制到构建文件夹，它们不会被更新。我做错了什么？

file(GLOB_RECURSE SOURCES *.cpp)
file(GLOB_RECURSE QMLS *.qml)

add_library(MyLib SHARED ${SOURCES} ${QMLS})

foreach(QmlFile ${QMLS})
  add_custom_command(TARGET MyLib POST_BUILD
                     COMMAND ${CMAKE_COMMAND} -E copy_if_different
                     ${QmlFile} $<TARGET_FILE_DIR:MyLib>)
endforeach()

Answer 1

虽然 Angew 的 answer 很好，但可以消除使用额外的目标。为此，add_library 调用应使用 已复制 .qml 文件（而不是 原始 文件，如问题帖子中的脚本）：

# This part is same as in Angew's answer
set(copiedQmls "")
foreach(QmlFile ${QMLS})
  get_filename_component(nam ${QmlFile} NAME)
  add_custom_command(
    OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${nam}
    COMMAND ${CMAKE_COMMAND} -E copy_if_different ${QmlFile} ${CMAKE_CURRENT_BINARY_DIR}
    DEPENDS ${QmlFile}
    COMMENT "Copying ${QmlFile}"
    VERBATIM
  )
  list(APPEND copiedQmls ${CMAKE_CURRENT_BINARY_DIR}/${nam})
endforeach()

# But instead of creating new target, we reuse library one.
add_library(MyLib SHARED ${SOURCES} ${copiedQmls})

当库target被构建时，它会触发add_library调用中的non-sources文件被更新（如果有对应的add_custom_command调用），但是更新非源文件不会强制重建库文件。这就是为什么您的原始代码无法按预期工作的原因。

注意，由于 CMake 无法将 .qml 文件识别为源文件，因此您不需要为它们设置 GENERATED 属性，如 here 所述。

Answer 2

您正在使用add_custom_command 的TARGET 签名，这意味着这些命令是作为构建TARGET 的一部分执行的。在您的情况下，POST_BUILD，这意味着命令将在MyLib 的构建完成后运行。如果MyLib 是最新的并且不需要重新构建，则命令将不会运行。

您可能希望改用输出生成签名 (OUTPUT)。像这样的：

set(copiedQmls "")
foreach(QmlFile ${QMLS})
  get_filename_component(nam ${QmlFile} NAME)
  add_custom_command(
    OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${nam}
    COMMAND ${CMAKE_COMMAND} -E copy_if_different ${QmlFile} ${CMAKE_CURRENT_BINARY_DIR}
    DEPENDS ${QmlFile}
    COMMENT "Copying ${QmlFile}"
    VERBATIM
  )
  list(APPEND copiedQmls ${CMAKE_CURRENT_BINARY_DIR}/${nam})
endforeach()

add_custom_target(
  CopyQMLs ALL
  DEPENDS ${copiedQmls}
)

请注意，很遗憾，add_custom_command 的 OUTPUT 参数不支持生成器表达式，因此无法在此处使用 $<TARGET_FILE_DIR>。我在上面的示例中使用了${CMAKE_CURRENT_BINARY_DIR}，您可能需要对其进行自定义以满足您的需求。 ${CMAKE_CFG_INTDIR} 可用于指定多配置生成器的每个配置目录。

请注意我上面的代码中存在额外的自定义目标。这是必要的，因为 CMake 只会在某些依赖于该输出的情况下执行生成输出的自定义命令。自定义命令通过在其DEPENDS 部分中列出输出来做到这一点。