fmap fmap 如何应用于函数（作为参数）？

Question

我试图了解fmap fmap 如何应用于像(*3) 这样的函数。

fmap fmap的类型：

(fmap fmap):: (Functor f1, Functor f) => f (a -> b) -> f (f1 a -> f1 b)

(*3) 的类型：

(*3) :: Num a => a -> a

也就是说签名a -> a对应f (a -> b)，对吧？

Prelude> :t (fmap fmap (*3))
(fmap fmap (*3)):: (Num (a -> b), Functor f) => (a -> b) -> f a -> f b

我尝试过创建一个简单的测试：

test :: (Functor f) => f (a -> b) -> Bool 
test f = True

然后将(*3) 输入其中，但我明白了：

*Main> :t (test (*3))

<interactive>:1:8:
    No instance for (Num (a0 -> b0)) arising from a use of ‘*’
    In the first argument of ‘test’, namely ‘(* 3)’
    In the expression: (test (* 3))

为什么会这样？

Answer 1

当你不知道自己在做什么时，多态是危险的。 fmap 和 (*) 都是多态函数，盲目使用它们会导致代码非常混乱（并且可能不正确）。我之前回答过类似的问题：

What is happening when I compose * with + in Haskell?

在这种情况下，我相信查看值的类型可以帮助您找出问题所在以及如何纠正问题。让我们从fmap的类型签名开始：

fmap :: Functor f => (a -> b) -> f a -> f b
                     |______|    |________|
                         |            |
                      domain      codomain

fmap 的类型签名很容易理解。它将函数从 a 提升到 b 到函子的上下文中，无论函子是什么（例如，列表、可能、两者之一等）。

“域”和“共域”这两个词分别表示“输入”和“输出”。无论如何，让我们看看当我们将fmap 应用到fmap 时会发生什么：

fmap :: Functor f => (a -> b) -> f a -> f b
                     |______|
                         |
                       fmap :: Functor g => (x -> y) -> g x -> g y
                                            |______|    |________|
                                                |            |
                                                a    ->      b

如您所见，a := x -> y 和 b := g x -> g y。此外，还添加了Functor g 约束。这给了我们fmap fmap的类型签名：

fmap fmap :: (Functor f, Functor g) => f (x -> y) -> f (g x -> g y)

那么，fmap fmap 是做什么的？第一个fmap 将第二个fmap 提升到函子f 的上下文中。假设f 是Maybe。因此，关于专业化：

fmap fmap :: Functor g => Maybe (x -> y) -> Maybe (g x -> g y)

因此，fmap fmap 必须应用于带有函数的 Maybe 值。 fmap fmap 所做的是将 Maybe 值内的函数提升到另一个仿函数 g 的上下文中。假设g 是[]。因此，关于专业化：

fmap fmap :: Maybe (x -> y) -> Maybe ([x] -> [y])

如果我们将fmap fmap 应用于Nothing，那么我们得到Nothing。但是，如果我们将它应用于Just (+1)，那么我们会得到一个函数，该函数会增加列表中的每个数字，并包装在Just 构造函数中（即我们得到Just (fmap (+1))）。

不过，fmap fmap 更通用。它实际上是做什么的，它在函子f（无论f 可能是什么）内部进行查找，并将f 中的函数提升到另一个函子g 的上下文中。

到目前为止一切顺利。所以有什么问题？问题是当您将fmap fmap 应用于(*3) 时。这是愚蠢和危险的，就像酒后驾车一样。让我告诉你为什么它是愚蠢和危险的。看看(*3)的类型签名：

(*3) :: Num a => a -> a

当您将fmap fmap 应用于(*3) 时，仿函数f 专用于(->) r（即一个函数）。函数是有效的函子。 (->) r 的 fmap 函数只是函数组合。因此，fmap fmap 的类型是：

fmap fmap :: Functor g => (r -> x -> y) -> r -> g x -> g y

-- or

(.)  fmap :: Functor g => (r -> x -> y) -> r -> g x -> g y
                          |___________|
                                |
                              (*3) :: Num a => a ->    a
                                               |       |
                                               |    ------
                                               |    |    |
                                               r -> x -> y

你明白它为什么愚蠢和危险吗？

1. 这很愚蠢，因为您正在将一个函数应用到一个只有一个参数 (*3) :: Num a => a -> a 的函数上，该函数需要一个带有两个参数 (r -> x -> y) 的输入函数。
2. 这很危险，因为(*3) 的输出是多态的。因此，编译器不会告诉您您正在做一些愚蠢的事情。幸运的是，由于输出是有界的，你会得到一个类型约束 Num (x -> y)，这应该表明你在某个地方出错了。

找出类型，r := a := x -> y。因此，我们得到以下类型签名：

fmap . (*3) :: (Num (x -> y), Functor g) => (x -> y) -> g x -> g y

让我告诉你为什么使用值是错误的：

  fmap . (*3)
= \x -> fmap (x * 3)
             |_____|
                |
                +--> You are trying to lift a number into the context of a functor!

您真正想做的是将fmap fmap 应用于(*)，这是一个二元函数：

(.) fmap :: Functor g => (r -> x -> y) -> r -> g x -> g y
                         |___________|
                               |
                              (*) :: Num a => a -> a -> a
                                              |    |    |
                                              r -> x -> y

因此，r := x := y := a。这为您提供了类型签名：

fmap . (*) :: (Num a, Functor g) => a -> g a -> g a

当您看到这些值时，这更有意义：

  fmap . (*)
= \x -> fmap (x *)

因此，fmap fmap (*) 3 就是 fmap (3*)。

最后，你的test 函数也有同样的问题：

test :: Functor f => f (a -> b) -> Bool

在特化函子 f 到 (->) r 上，我们得到：

test :: (r -> a -> b) -> Bool
        |___________|
              |
            (*3) :: Num x => x ->    x
                             |       |
                             |    ------
                             |    |    |
                             r -> a -> b

因此，r := x := a -> b。因此我们得到类型签名：

test (*3) :: Num (a -> b) => Bool

由于a 和b 都没有出现在输出类型中，因此必须立即解决约束Num (a -> b)。如果a 或b 出现在输出类型中，那么它们可以被特化并且可以选择Num (a -> b) 的不同实例。然而，因为它们没有出现在输出类型中，编译器必须立即决定选择Num (a -> b) 的哪个实例；因为Num (a -> b) 是一个没有任何实例的愚蠢约束，所以编译器会抛出一个错误。

如果您尝试test (*)，那么您将不会收到任何错误，原因与我上面提到的相同。