在 Haskell 中有没有更好的方法来做到这一点？

Question

我写了以下内容来帮助大孩子完成他们的家庭教育工作，并通过学习如何编程来保持头脑工作（我认为 haskell 听起来很棒）。

main :: IO ()
main = do
   putStrLn "Please enter the dividend :"
   inputx  <- getLine
   putStrLn "Please enter the divisor :"
   inputy  <- getLine
   let x = (read inputx) :: Int
   let y = (read inputy) :: Int
   let z = x `div` y
   let remain = x `mod` y
   putStrLn ( "Result: " ++ show x ++ " / " ++ show y ++ " =  " ++ show z ++  " remainder " ++ show remain )

   putStrLn ( "Proof: (" ++ show y ++ " x " ++ show z ++ ") = " ++ show (y * z) ++ " + " ++ show remain ++ " = " ++ show ((y * z) + remain))
   putStrLn ( "Is this what you had? ")

他们这样做是不是更整洁/更好/更好/更紧凑的方式？

Answer 1

这将受益于一个关键原则：尽可能将纯代码与 IO 分开。这将使您的程序扩大规模并保持main breif。在一个大的main 中包含大量let 并不是一种非常实用的方法，并且随着代码的增长往往会变得更加混乱。

使用类型签名和readLn（本质上是fmap read getLine）有助于减少一些麻烦。 （如果您不熟悉fmap，请访问问题How do functors work in haskell?。fmap 确实是一个非常灵活的工具。）

getInts :: IO (Int, Int)
getInts = do
    putStrLn "Please enter the dividend :" 
    x <- readLn 
    putStrLn " Please enter the divisor :"
    y <- readLn
    return (x,y)

现在正在处理。如果我用这种数据做更多的事情，或者更频繁地，我会使用记录类型来存储被除数、除数、商和余数，因此请记住这一点，以备将来使用，但这在这里有点过头了。

我返回的是一个列表而不是一个元组，所以我可以使用 map 到 show 全部：

sums :: (Int, Int) -> [Int]
sums (x,y) = [x, y, q, r, y * q, y * q + r] where
            q = x `div` y
            r = x `mod` y

拼图的最后一块是输出。同样，我更喜欢在外部生成这个 IO，然后我可以稍后在其上使用mapM_ putStrLn 来打印每一行。我更喜欢这个记录类型，但我容忍一个字符串列表作为输入，因为我假设我已经shown 他们全部了。

explain :: [String] -> [String]
explain [x,y,q,r,yq,yq_r] = 
  [ concat ["Result: ", x, " / ", y, " =  ", q, " remainder ", r]
  , concat ["Proof: (", y, " x ", q, ") + ", r, " = ", yq, " + ", r, " = ", yq_r]
  , "Is this what you had? "]

现在我们可以把main写成

main = do (x,y) <- getInts
          let ns = map show ( sums (x,y) )
              es = explain ns
          mapM_ putStrLn es

或者更简洁，通过将函数explain . map show . sums 连接在一起，然后使用fmap 将其应用于getInts 的输出：

main :: IO ()
main = fmap (explain . map show . sums) getInts
       >>= mapM_ putStrLn

您可能会注意到我在证明中添加了一个+r 以使= 始终表示=，这是正确的数学用法，以及mirror 的Haskell 对= 的含义。