如何在 Excel VBA 中访问 Word 公共变量

Question

我正在尝试自动生成一些由 Excel VBA 完成所有工作的报告。我的雇主有一套标准化的模板，所有文件都应该从中生成。我需要从 Excel VBA 填充这些模板之一。 Word 模板广泛使用 VBA。

这是（部分）我的 Excel VBA 代码：

Sub GenerateReport() ' (Tables, InputDataObj)
  ' code generating the WordApp object (works!)

  WordApp.Documents.Add Template:="Brev.dot"

  ' Getting user information from Utilities.Userinfo macro in Document
  Call WordApp.Run("Autoexec") ' generating a public variable
  Call WordApp.Run("Utilities.UserInfo")
  ' more code
End sub

在 Word VBA Autoexec 模块中，定义并声明了一个名为 user 的公共变量。来自Utilities 模块的Userinfo 子填充user。这两个例程都在没有任何 VBA 投诉的情况下运行。然后我希望能够访问我的 Excel VBA 中的 user 变量，但我收到以下错误

编译错误：尚未在此上下文中创建变量。

如何在 Excel VBA 中访问 Word VBA 变量？我认为它或多或少是一样的？

编辑：user 变量是用户定义的Type，只有String 属性。复制填充user 变量的 Word VBA 函数是绝对可行的，只是比我认为的需要更多的工作......

Answer 1

在 Word 模块中：

Public Function GetUserVariable() As String '// or whatever data type
    GetUserVariable = user
End Function

在 Excel 模块中：

myUser = WordApp.Run("GetUserVariable")

---

或者，您可以复制变量值 - 因为它被称为 user 我怀疑它正在返回有关文档的用户或作者的一些信息。在这种情况下，您可能会遇到以下情况之一：

'// Username assigned to the application
MsgBox WordApp.UserName

'// Username defined by the system
MsgBox Environ$("USERNAME")

'// Name of the author of the file specified
MsgBox CreateObject("Shell.Application").Namespace("C:\Users\Documents").GetDetailsOf("MyDocument.doc", 9)

Answer 2

另一种选择 - 如果您只能在 Utilities.UserInfo 子代码中添加一行代码（在设置您的公共变量之后）：

ActiveDocument.Variables("var_user") = user

然后您可以在 Excel 中轻松访问它：

Sub GenerateReport() ' (Tables, InputDataObj)
  ' code generating the WordApp object (works!)

  'I am assuming your WordApp object is public, as you don't declare it.
  'Capture the new document object    
  Dim newdoc as Object
  set newdoc = WordApp.Documents.Add(Template:="Brev.dot")

  ' Getting user information from Utilities.Userinfo macro in Document
  Call WordApp.Run("Autoexec") ' generating a public variable
  Call WordApp.Run("Utilities.UserInfo")

  'Get and show the value of "user"
  Dim user as String
  user = newdoc.Variables("var_user")
  msgbox, user
End Sub

这是假设user是一个字符串。

编辑：由于要求仅在 Excel VBA 上工作，我肯定会尝试 Scott 和 MacroMan 建议的方法 - 如果可能的话，在 Excel 中复制 Word 宏的相同功能。

我假设您已经排除了使用原始模板的编辑副本、设置在公共文件夹中的可能性...

为了完整起见，还有另一种可能性：实际上可以在没有 VBProject 对象模型的情况下通过“蛮力”在 Word 文档中注入 VBA 代码。如果您将 Word 文档重命名为 .zip 文件并打开它，您会注意到其中有一个 \word\vbaProject.bin 文件。此文件包含文档的 VBA 项目，原则上可以通过修改或替换来添加或更改 VBA 代码。

我做了一些测试，通过简单地复制 vbaProject.bin 文件将代码从一个文档移植到另一个文档，并且这个概念有效。如果您有兴趣了解有关此文件的更多信息，this topic 可能会有所帮助。

但是请注意，使用这种技术做您想做的事情会有些复杂（对于初学者来说，这将涉及从您的 Excel VBA 更新 zip 文件），并且需要大量的实验来降低风险意外损坏您的文件。如果您正在寻找一种简单易行的解决方案，则绝对不推荐使用 - 但这是可能的。