如何将当前价格从网站导入excel？答案

【问题标题】：How do I import current price from site into excel?如何将当前价格从网站导入excel？
【发布时间】：2017-10-21 06:09:45
【问题描述】：

目前我在 excel 中使用它来导入股票价格：

这是来自雅虎财经，使用简单，我可以按 CTRL-ALT-F9 自动更新所有单元格并让最新价格填充单元格。

如何从其他站点导入更改的号码？我尝试过使用诸如“数据>获取和转换数据>从网络”之类的方法，但没有成功。

我想要完成的是在http://preev.com/ 上显示当前价格并在我按下 CTRL-ALT-F9 时更新为最新价格的 excel 单元格

【问题讨论】：

您愿意接受涉及编写代码的答案吗？
当然可以，只要全部集成到excel中即可。越简单越好，但有工作总比没有好:)
如果除了 Excel 之外还使用 Python，那么获得所需数据的机会就会增加。（JS 和 Ruby 也可以，但 Python 是我所知道的。）除了WEBSERVICE() 之外，Excel 是否有任何用于导入外部数据的功能？
引用是否需要来自该页面？我有另一个 BTC 数据源，以及使用 api 获取它的代码。
它可能来自另一个来源，我已经有一段时间没有用 Python 编码了，但如果它与 excel 配合良好，我愿意使用它。

标签： excel web-services bitcoin auto-update stock

【解决方案1】：

这里是UDF写成VBA返回当前比特币现货价格。如所写，它将使用 ctrl-alt-F9 进行更新。默认返回是spot 价格。它还将返回带有适当参数的buy 或sell。

不要忘记按照代码所示设置引用。

在工作表上：

=CurrBitCoinPrice()

常规模块

Option Explicit
'Set Reference to: Microsoft WinHTTP services, Version 5.1
'                  Microsoft VBScript Regular Expressions 5.5

Function CurrBitCoinPrice(Optional BSSp As Long = 3) as Currency
        '1:  Buy
        '2:  Sell
        '3:  Spot

Application.Volatile

    Dim httpRequest As WinHttpRequest
    Dim sResponse(2) As String
    Dim RE As Object, MC As Object
    Dim sType
    Const sInfo As String = "?currency=USD"
    Dim vRes As Variant
    Dim I As Long

sType = Array("buy", "sell", "spot")

Const sUrl As String = "https://api.coinbase.com/v2/prices/"


For I = 0 To 2
Set httpRequest = New WinHttpRequest
With httpRequest
    .Open "Get", sUrl & sType(I) & sInfo
    .Send
    .WaitForResponse

    sResponse(I) = .ResponseText
End With
Set httpRequest = Nothing
Next I

Set RE = New RegExp
With RE
    .Pattern = "\d*\.?\d+"
    .Global = False
End With
ReDim vRes(0 To 1, 1 To 3)
    vRes(0, 1) = "Buy"
    vRes(0, 2) = "Sell"
    vRes(0, 3) = "Spot"

    For I = 0 To 2
        If RE.Test(sResponse(I)) = True Then
            Set MC = RE.Execute(sResponse(I))
            vRes(1, I + 1) = MC(0)
        End If
    Next I

CurrBitCoinPrice = vRes(1, BSSp)

End Function

【讨论】：

我试了一下，报错了，当我点击ok的时候，上面的文字被高亮了，我把它放在了一个红框里：i.imgur.com/4ZnSVgC.png
感谢您提供了相关信息（很多人没有）。宏的第二行和第三行 (Set Reference) 表示你没有做的事情。
@Karl 设置引用后运气好吗？
我搞定了，非常感谢！感谢您的帮助:)
既然这似乎已经回答了你的问题，如果你能将我的回答标记为答案（左上角的小复选标记），我将不胜感激。

【解决方案2】：

我看到了这个解决方案，并且对您的问题也有同样的看法：

excel-convert-external-links-to-values

如果你不喜欢这种方法，我会搜索这种不同的方法

【讨论】：