如何以编程方式添加对 VBA 项目的引用？

Question

我正在部署一个需要 Scripting.Dictionary 和 RegExp 的早期绑定样式的 VBA 模块。

可以预见，该脚本在另一台计算机上运行时会失败。 用户必须转到 VBA IDE 中的 Tools->Reference 并手动添加对这两个库的引用才能使其工作。

这就是问题所在。要求非技术最终用户转到 IDE 并手动添加引用对他们的要求太多了。

另一种选择是重写整个（由其他人编写的非常长的脚本）以使用后期绑定。如果有其他方法，我宁愿不走这条路。

作为替代方案，有些人建议像这样以编程方式添加引用：

Application.VBE.ActiveVBProject.References.AddFromFile [Path to library]

1. 这是正确的解决方案吗？如果是，此策略有什么缺点吗？
2. 如果没有，是否有其他方法可以使代码保持早期绑定但不需要用户手动添加引用。

也欢迎直接调用 Win32/64 API 的建议。

谢谢。

Answer 1

在我自己有限的环境中（少数其他人使用我开发的电子表格，相对标准的机器设置），如果我创建文件并添加引用，然后将副本提供给其他人，他们可以打开它而无需问题而不必做任何事情，因此请记住此答案。 （我想知道为什么这对你不起作用。）另外，这是使用 Excel 的。

您可以考虑使用 GUID 属性，而不是从文件路径添加引用。

这是我曾经用来在新创建的工作簿中自动创建引用的一些代码。 （它是脚本的一部分，可以将工作表上的代码、引用和单元测试导出为文本以供 Subversion 使用，然后从文本文件中重新构建工作簿。）您可能会发现它对您的情况很有用。 （EH 和清理已删除以保持简短...）

'Export refs in existing workbook to text file
Private Sub exportRefs_(srcWbk As Workbook)
    Dim fs As FileSystemObject
    Set fs = New FileSystemObject

    Dim tsout As TextStream
    Set tsout = fs.CreateTextFile(fs.BuildPath(getTargetPath_(srcWbk), "refs.refs"))

    Dim ref As Reference
    For Each ref In Application.ThisWorkbook.VBProject.References
        Call tsout.WriteLine(ref.GUID)
    Next ref

    '<EH + cleanup...>
End Sub


'Add refs to newly created workbook based on previously exported text file
Private Sub importRefs_(wbk As Workbook, path As String)
    Dim fs As FileSystemObject
    Set fs = New FileSystemObject

    Dim tsin As TextStream
    Set tsin = fs.OpenTextFile(path)

    Dim line As String
    Dim ref As Reference

    While Not tsin.AtEndOfStream
        line = tsin.ReadLine()

        Set ref = Nothing

        On Error Resume Next
            Set ref = wbk.VBProject.References.AddFromGuid(line, 0, 0)
        On Error GoTo 0

        If ref Is Nothing Then
            Debug.Print "add failed: " & line
        End If
    Wend

    '<EH + cleanup...>
End Sub

就像我说的，有限的环境，但希望它有所帮助。