如果工作表存在，请不要添加另一个工作表

Question

如果工作表“数据”不存在，则代码工作正常，如果确实存在，但我收到错误“名称已存在，请尝试其他名称”。我只是用On Error GoTo ErrorHandler 解决了这个问题，但是问题是在代码运行并且宏触发错误处理程序 msgbox 之后，它仍然会创建一个新工作表（名称为'Sheet1,2,3，... ')。

片段：

Sub AddWorkSheet()
    Dim wb As Workbook, shtDest As Worksheet
    On Error GoTo ErrorHandler
    Sheets.Add.Name = ("Data")
    Set shtDest = Sheets("Data")

ErrorHandler:
    MsgBox ("Something went wrong."), vbCritical

End Sub

如果工作表“数据”已经存在，我希望代码只返回消息框而不创建任何其他工作表。

Answer 1

在添加工作表之前，检查它是否存在：

Function ShtExist(ShtName As String) As Boolean
On Error Resume Next
    ShtExist = Len(ThisWorkbook.Sheets(ShtName).Name) > 0
On Error GoTo 0
End Function

Sub AddWorkSheet()

    Dim wb As Workbook, shtDest As Worksheet
    If ShtExist("Data") Then
    MsgBox ("Something went wrong."), vbCritical
    Else
    Sheets.Add.Name = ("Data")
    Set shtDest = Sheets("Data")
    End If

End Sub

Answer 2

当您尝试将不存在的工作表分配给变量时，VBA 将返回错误 9。从我的 POV 来看，我认为捕获该错误然后在需要时创建工作表很有用。

所以我会使用：

Sub AddWorkSheet()
Dim wb As Workbook, shtDest As Worksheet

On Error GoTo ErrorHandler
Set shtDest = Sheets("Data")


'<--rest of your code-->
'
'
'
'
'
'
''<--rest of your code-->

Set shtDest = Nothing
Set wb = Nothing

Exit Sub


ErrorHandler:
If Err.Number = 9 Then
    'must create worksheet DATA
    Sheets.Add.Name = ("Data")
    Set shtDest = Sheets("Data")
    Resume Next
Else
    'different error. MSgbox with new error
    MsgBox Err.Description, vbCritical, Err.Number
    Stop
End If
End Sub

请注意，在 ErrorHanlder 部分之前，我添加了 Exit Sub 以避免每次子运行时都执行这部分代码。

Answer 3

（编辑：此答案的先前版本产生了错误的结果，详细信息在 cmets 中。）

这应该可行。注意On Error Resume Next 与On Error GoTo 0 结合使用，而不是On Error GoTo ErrorHandler。 （GoTo 语句通常与 so-called "spaghetti code" 相关联，因此尽可能避免使用它们可能是一个好习惯。）

Sub AddWorkSheet()
    Dim wb As Workbook, ws As Worksheet
    On Error Resume Next
    Set ws = Worksheets("Data")
    If Err.Number <> 9 Then ' 9 means subscript out of range
        MsgBox ("Sheet already exists."), vbCritical
    Else
        Sheets.Add After:=Worksheets(Worksheets.Count)
        Sheets(Worksheets.Count).Name = "data"
    End If
    On Error GoTo 0
End Sub

在您的原始代码中，您可以在错误处理程序之前添加一个Exit Sub 语句；没有它ErrorHandler 将始终被调用。 （您可能想看看documentation。）。