嵌套的 RESTful 资源

Question

我正在使用 Grails 在 2.3 中引入的对 REST 的支持。我的应用包含以下域类：

@Resource(formats=['json', 'xml'])
class Sensor {
    String name
    static hasMany = [metrics: Metric]
}

@Resource(formats=['json', 'xml'])
class Metric {

    String name
    String value

    static belongsTo = [sensor: Sensor]
}

在UrlMappings.groovy 中，我定义了以下嵌套的 RESTful URL 映射：

"/api/sensors"(resources: 'sensor') {
    "/metrics"(resources: "metric")
}

如果我导航到 URL /api/sensors/1/metrics，我希望响应显示与 ID 为 1 的 Sensor 关联的所有 Metric 实例，但实际上它返回所有 Metric 实例（最多 10 个)

• 是否有一个 URL 将只返回与特定 Sensor 实例关联的 Metric 实例（不实现我自己的控制器）？
• 有没有办法覆盖 10 个结果的默认限制（不向请求添加 max 参数）？

Answer 1

看起来没那么简单。 :) 如果运行这个命令，我们可以得到一幅生动的画面：

grails url-mapping-report

看

Controller: metric
 |   GET    | /api/sensors/${sensorId}/metrics           | Action: index  |
 |   GET    | /api/sensors/${sensorId}/metrics/create    | Action: create |
 |   POST   | /api/sensors/${sensorId}/metrics           | Action: save   |
 |   GET    | /api/sensors/${sensorId}/metrics/${id}     | Action: show   |
 |   GET    | /api/sensors/${sensorId}/metrics/${id}/edit| Action: edit   |
 |   PUT    | /api/sensors/${sensorId}/metrics/${id}     | Action: update |
 |  DELETE  | /api/sensors/${sensorId}/metrics/${id}     | Action: delete |

因此，我们至少需要一个 MetricController 继承 RestfulController 并覆盖 index() 以对 Metric 进行额外检查，并根据 Sensor 返回列表，如下所示：

class MetricController extends RestfulController<Metric> {
    static responseFormats = ['json', 'xml']

    MetricController() {
        super(Metric)
    }

    @Override
    def index() {
        def sensorId = params.sensorId
        respond Metric.where {
            sensor.id == sensorId
        }.list()
    }
}

以上更改将为/api/sensors/1/metrics 提供预期结果（包括对分页结果的限制）。