Newsoft JSON .NET 反序列化为 VB.net 中具有私有属性的对象

Question

我目前正在编写一个 API，它从使用 Newsoft JSON .NET 库在 VB.net 中处理它的 Web 服务中获取对象。

我正在将名为 Vehicles 的 JSON 数组反序列化为车辆列表。

这里是重要的代码sn-ps：

Public Class VehicleList
    Public Vehicles() As Vehicle
End Class

Public Class Vehicle
    Public Property licence_plate_number As String
End Class

这里我们有一个 Web 客户端，它抓取 json 并将其放入对象中。

Public Class dcVehicles

    Private Property _Vehicles As VehicleList

    Public ReadOnly Property Vehicle As Vehicle()
        Get
            Return _Vehicles.Vehicles
        End Get
    End Property

    Public Sub Refresh()
        _Vehicles = JsonConvert.DeserializeObject(Of VehicleList)(wcReply, jsSettings)
    End Sub
End Class

还有更多内容（减少）。 所以一切都按预期工作，json net 正在创建一系列车辆。

我正在尝试通过将车辆类中的属性设置为私有和只读来实现这一点，使用 api 的应用程序应该无法设置这些。

问题是我尝试更改车辆类中的公共属性以保持属性私有并允许只读，如下所示：

Public Class Vehicle
    Friend Property licence_plate_number As String

    Public ReadOnly Property RegistrationNumber As String
        Get
            Return licence_plate_number
        End Get
    End Property
End Class

然后我得到的问题是 JSON.net 无法填充车辆。所有 3 个类都在同一个命名空间中。 所以我尝试了使用 Friend/private 访问级别修饰符的 licence_plate_number，但 Json 网络仍然无法填充该对象。

唯一的办法就是保持公开。

有人有解决方法的想法吗？还是我错过了一些简单的东西？

谢谢

Answer 1

如果您只想使用 Json.NET 序列化 Private 或 Friend 属性，请将其标记为 <JsonProperty> 并将您不想序列化的公共只读属性标记为 <JsonIgnore>：

Public Class Vehicle
    <JsonProperty> _
    Friend Property licence_plate_number As String

    <JsonIgnore> _
    Public ReadOnly Property RegistrationNumber As String
        Get
            Return licence_plate_number
        End Get
    End Property
End Class

演示fiddle.

但是如果你真的想要 licence_plate_number 属性的只读值语义以便在构造后无法设置它，你可以通过将默认构造函数替换为单个参数化构造函数并匹配构造函数参数来做到这一点JSON 属性名称的名称，如下所示：

Public Class Vehicle
    Private Readonly licence_plate_number As String

    Public Sub New(ByVal licence_plate_number as String)
        Me.licence_plate_number = licence_plate_number
    End Sub

    <JsonProperty("licence_plate_number")> _
    Public ReadOnly Property RegistrationNumber As String
        Get
            Return licence_plate_number
        End Get
    End Property
End Class

当有一个参数化的公共构造函数时，Json.NET 将调用它，使用反射按名称将构造函数参数与 JSON 属性匹配，并使用缺失属性的默认值。按名称匹配不区分大小写，除非有多个仅大小写不同的匹配项，在这种情况下，匹配项区分大小写。

演示fiddle。

如果您的类有多个公共构造函数，请将要使用的一个标记为<JsonConstructor>。