创建后如何更改 DataModule 的所有者？

Question

我正在尝试将 DataModule 传递给表单构造函数中的表单。我还希望表单成为 DataModule 的“所有者”，以便表单在关闭时破坏 DataModule。这产生了两个对象在其构造函数中相互需要的问题。

我试图在创建后设置 DataModule 的所有者，但这是一个只读属性。

我的第二个表单如下所示：

type
  TSecondPopup = class(TForm)
  private
    FMyData: TMyData;
  public
    constructor Create(MyData: TMyData); reintroduce;
  end;

var
  SecondPopup: TSecondPopup;

implementation

{$R *.dfm}


constructor TSecondPopup.Create(MyData: TMyData);
begin
  FMyData := MyData;

  inherited Create(nil);
end;

我的数据模块中没有特殊代码。

在我的主窗体中，我想在显示第二个窗体时做这样的事情：

procedure TMainApp.Button1Click(Sender: TObject);
var
  MyData: TMyData;
  SecondPopup: TSecondPopup;
begin
  MyData := TMyData.Create(nil);
  SecondPopup := TSecondPopup.Create(MyData);

  // Can't change owner now.  It is a read only property. 
  // MyData.Owner := SecondPopup;

  SecondPopup.Show;
end;

我知道我可以将 DataModule 更改为表单上的一个属性。然后我可以先创建表单，然后创建设置所有者的数据模块，最后在表单上设置属性。我正在尝试在这个项目上使用构造函数依赖注入。当我有一个将主表单传递给多个表单的共享数据模块时，它一直工作得很好。在这种情况下，主窗体会保留数据模块，直到它存在。在这种情况下，只有一个表单需要这个数据模块，所以我想通过设置所有者来强制它管理数据模块的生命周期。

另一种选择是在我关闭第二个表单时显式释放 DataModule。但是，该表单无法知道调用者是否也将数据模块传递给了不同的表单。

有没有办法使用构造函数来注入我的对象，但仍然获得表单来管理生命周期？

目前使用 Delphi XE3。

Answer 1

使用NewOwner.InsertComponent(TheComponent) 可以更改组件的所有权。而且由于一个组件一次只能由一个组件拥有，因此 RTL 会自动从前一个所有者那里移除所有权。

---

但是……

另一种选择是在我关闭第二个表单时显式释放 DataModule。但是，该表单无法知道调用者是否也将数据模块传递给了不同的表单。

如果您希望将单个 DataModule 传递给多个 Form，那么更改 DataModule 的所有权不是解决方案：拥有 DataModule 的一个 Form 将无法决定是否可以释放 DataModule。因此，结论是 DataModule 不能被任何表单拥有，除了 MainForm。 （那么我宁愿让它由 Application 对象拥有，但这只是个人喜好问题。）

随后，您需要在 DataModule 中为它所附加的表单提供一个引用计数机制。

Answer 2

您不必更改 DataModule 的 Owner。您可以随时简单地销毁 DataModule，即使它分配了 Owner。当 DataModule 被释放时，它会简单地将自己从其Owner 中删除，因此不会再次被释放。如果您采用这种方法，您还应该添加对 FreeNotification() 的调用，以便在您的表单仍在引用 DataModule 时（通过其 Owner 或其他任何人）获得通知：

protected
  procedure Notification(AComponent: TComponent; Operation: TOperation); override;

constructor TSecondPopup.Create(MyData: TMyData);
begin
  inherited Create(nil);
  FMyData := MyData;
  if FMyData <> nil then
    FMyData.FreeNotification(Self);
end;

destructor TSecondPopup.Destroy;
begin
  if FMyData <> nil then
    FMyData.RemoveFreeNotification(Self);
  inherited Destroy;
end;

procedure TSecondPopup.Notification(AComponent: TComponent; Operation: TOperation);
begin
  inherited Notification(AComponent, Operation);
  if (Operation = opRemove) and (AComponent = FMyData) then
    FMyData := nil;
end;

如果您绝对想更改 DataModule 的 Owner，这也是可行的，通过 TComponent.RemoveComponent() 和 TComponent.InsertComponent() 方法：

constructor TSecondPopup.Create(MyData: TMyData);
begin
  inherited Create(nil);
  FMyData := MyData;
  if FMyData <> nil then
  begin
    // InsertComponent() will call RemoveComponent() internally for you...
    Self.InsertComponent(FMyData);
  end;
end;

Answer 3

您想让表单拥有数据模块。由于所有权是在构建时最自然地指定的，因此结论是应该首先创建表单。

因此，不要将数据模块传递给表单的构造函数，而是传递一些允许表单调用数据模块的实例化的东西。例如，您可以将一个函数传递给表单的构造函数，该函数接受表单作为参数并返回新生成的数据模块。例如。

type
  TCreateDataModule = function(Owner: TMyForm): TMyDataModule of object;

---

您完全可以在表单之外创建没有所有者的数据模块。将对象传递给表单构造函数。然后表单可以在其析构函数中销毁数据模块。这对我来说听起来是最干净的解决方案。我发现很难看到这个选项。

我认为您已经考虑过这个选项，但出于以下原因拒绝了它：

但是该表单无法知道调用者是否也将数据模块传递给了不同的表单。

如果是这样，那么没有什么可以拯救你。您不能让两个对象都负责生命周期，除非它们使用引用计数或类似方法。

Answer 4

为什么要在创建表单之前创建一个供表单使用的数据模块？ 1）为什么不直接将Data Module单元添加到表单的接口使用列表中，在表单中声明一个Data Module类型的私有变量，并在表单的OnCreate事件中创建表单的Data Module变量......和然后你可以在 OnDestroy 事件中 FreeAndNil 数据模块。 此外，您可以进一步声明表单数据模块变量的公共属性，您可以使用它从调用单元（即TestForm.DataModule）访问数据模块

2) 如果您认为必须在表单之外创建数据模块，可能首先进行大量涉及数据模块的初始化、处理等，然后将数据模块传递给表单并忘记它......并假设您正在创建的这个表单，它将使用数据模块，将是一个非模态表单（那一点信息会有很大帮助），你总是可以做 1）{以上}首先，然后在调用表单的 Show 方法之前访问“TestForm.DataModule”以应用所有初始化、流程等。