如何加快 Microsoft Access 中的批量“更新插入”

Question

我正在使用 VBA 字典在 Access 中执行“更新插入”。我正在循环我的字典键，如果该键存在于 Access 表中，那么我将更新它。如果没有，它会插入它。然而，我的表包含 200k+ 行，这使得代码执行速度非常慢（例如，5 分钟甚至 5% 都没有完成），因为迭代需要在整个表中搜索“LOC”（我的键）。

有没有办法让我显着加快这个过程？ 我的代码如下，感谢任何帮助。

Sub UpdateDatabase(dict As Object)

Dim db As Database
Dim rs As DAO.Recordset

Set db = OpenDatabase("C:\XXX\myDB.accdb")
Set rs = db.OpenRecordset("MyTable", dbOpenDynaset)


For Each varKey In dict.Keys()

    'Table is searched for key
    rs.FindFirst "[LOCID] = '" & varKey & "'"
    If rs.NoMatch Then
        'If the key was not found, insert it
        rs.AddNew
        rs!LOCID = varKey
        rs![Status] = "To Start"
        rs.Update
    Else
        'If the key was found, update its status
        rs.Edit
        rs![Status] = "Done"
        rs.Update
    End If
Next

rs.Close
db.Close

Application.StatusBar = False
End Sub

编辑：

我在上面的代码中发现了瓶颈。这是行：

rs.FindFirst "[LOCID] = '" & varKey & "'"

这用于查找密钥是否在数据库中。删除它（并简单地插入新数据）加快了这个过程，并且在几秒钟内完成。有没有一种快速的方法来确定一个值是否已经在一个表中？

Answer 1

首先： dict 集合有多大。 （5、10 或 1000？）。

接下来，LOCID 是该表“MyTable”中的索引列。

如果 LOCID 已经是一个 N 索引列，那么您可以使用以下代码。它应该可以将速度提高大约 100 倍或更多倍：

假设该表不是链接表，实际上是数据库中的一个表。

请注意，您必须将有问题的表打开为“可操作”——这是默认设置，因此我删除了 dbOpenDynaset）

这段代码可以解决问题：

Dim db        As DAO.Database
Dim rs        As DAO.Recordset


Set db = OpenDatabase("C:\XXX\myDB.accdb")
Set rs = db.OpenRecordset("MyTable")     ' <--- note this!!!

rs.Index = "LOCID"

For Each varKey In dict.Keys()

  'Table is searched for key
  rs.Seek "=", varKey
  If rs.NoMatch = True Then
      'If the key was not found, insert it
      rs.AddNew
      rs!LOCID = varKey
      rs![Status] = "To Start"
      rs.Update
  Else
      'If the key was found, update its status
      rs.Edit
      rs![Status] = "Done"
      rs.Update
  End If
Next

rs.Close
db.Close

您还需要确定 LOCID 列上实际索引的名称。我在上面使用了 LOCID，但您最好使用访问权限打开数据库，将表格翻转到设计模式，然后点击功能区“索引”按钮。如果 LOCID 是主键，那么索引很有可能被命名为 PrimaryKey。所以你需要索引的名称。

Answer 2

听从别人的建议；基本上不做循环。执行操作查询（追加或更新）。

这是“程序员”和“数据库开发人员”之间最常见的区别......