VB.NET - 从 MySQL 数据库中获取价值并将其插入 Ms. Access (MDB) 数据库

Question

我想从 MySQL 导出数据库并将其导入 Ms. Access (MDB) 数据库。我尝试编写一个长 LoC 来处理将数据库导入 DataTable 变量并将值存储到其中。

这是我从 MySQL 上的 adm_users 数据库中获取价值的代码

a_query = "SELECT * FROM adm_users where uac_code='4' or uac_code='4A' or uac_code='1'"
a_da = New MySqlDataAdapter(a_query, db_conn)
a_da.Fill(a_ds, "adm_users")
a_dt = a_ds.Tables("adm_users")

然后我想使用此代码将 a_dt 值存储到 MDB 数据库中

For x = 0 To a_dt.Rows.Count - 1
    b_query = "INSERT INTO user_login
               (userid, username, password, uac) VALUES
               ('" + a_dt.Rows(x).Item("userid") + "', '" + a_dt.Rows(x).Item("username") + "', '" + a_dt.Rows(x).Item("userpwd") + "', '2')"
    b_sql = New OleDbCommand(b_query, ms_conn)
    b_sql.ExecuteReader()
Next

然后尝试查找存储在b_query中的字符串查询，看起来像这样

INSERT INTO user_login
                (userid, username, password, uac) VALUES
                ('admin', 'Varenicou', 'administrator', '2')

然后返回值为：“INSERT INTO 语句中的语法错误” 我发现查询没有问题，所以我将 b_query 变量替换为“SELECT FROM user_login”之类的简单查询，返回值为：“SELECT * FROM 语句中的语法错误”

也许我太笨了，不能问这个问题，但我认为 VB.NET 认为我已经打开了与 MySQL 数据库的连接，并且必须始终在 MySQL 数据库上。因此，当我打开与 Access 女士的数据库连接时，它会返回类似的值，并且 VB.NET 与“您想使用哪个数据库？”混淆

我有什么想法来完成这项任务吗？我已经向我的朋友询问了一些建议，他说我需要与班级合作，我也有另一个想法与另一个新项目合作，该项目通过首先将 MySQL 数据库导出为 CSV 来完成输入 Access 女士数据库的任务。

Answer 1

编辑：

重新阅读您的问题后，我可以告诉您，您遇到的具体问题是由于“密码”是 Jet/Access SQL 中的保留字。任何时候想要在 SQL 中使用保留字作为标识符，都需要对其进行转义。对于 Access，您可以通过将其括在括号中来做到这一点，例如

INSERT INTO user_login (userid, username, [password], uac)
VALUES (@userid, @username, @password, @uac)

我在下面的原始建议仍然有效。

原文：

如果您有一个DataTable，那么您就不会遍历它来保存数据。就像您在数据适配器上进行一次Fill 调用以检索数据一样，您也可以进行一次Update 调用来保存数据。当没有什么可读的时候，打电话给ExecuteReader 有什么意义？至少打电话给ExecuteNonQuery，但即使这样也不理想。

如果要插入其中包含的数据，则必须配置第二个数据适配器的InsertCommand。您还需要DataTable 中的所有DataRows 才能拥有RowState 的Added。为此，您只需在第一个数据适配器上将AcceptChangesDuringFill 设置为False。当您调用Fill 时，它会添加所有行，因此它们的RowState 是Added。然后它调用AcceptChanges，将所有RowStates 设置为Unchanged。告诉它不要调用AcceptChanges，你就可以插入了。

这是一个使用两个数据适配器从一个数据库获取数据并插入另一个数据库的示例：

Dim table As New DataTable

Using sourceAdapter As New MySqlDataAdapter("SELECT Column1, Column2 FROM MyTable",
                                            "source connection string here") With {.AcceptChangesDuringFill = False}
    sourceAdapter.Fill(table)
End Using

Using destinationConnection As New OleDbConnection("destination connection string here"),
      destinationCommand As New OleDbCommand("INSERT INTO MyTable (Column1, Column2) VALUES (@Column1, @Column2)",
                                             destinationConnection),
      destinationAdapter As New OleDbDataAdapter With {.InsertCommand = destinationCommand}
    With destinationCommand.Parameters
        .Add("@Column1", OleDbType.VarChar, 50, "Column1")
        .Add("@Column2", OleDbType.Integer, 0, "Column2")
    End With

    destinationAdapter.Update(table)
End Using

如您所见，这是相当简单的事情。一个带有SelectCommand 的数据适配器和另一个带有InsertCommand 的数据适配器。添加参数并没有什么特别之处，但您首先需要了解参数。如果您不知道如何在 ADO.NET 中使用参数，那么您应该立即学习。你可以找到我自己的解释here。