在 Access 2003 中编辑链接表信息

Question

我有一个 Access 2003 数据库，其中包含指向 SQL Server 2005 数据库的链接表。最近更新了用于在 Access 和 SQL Server 之间创建 ODBC 连接的用户信息（密码）。

当我打开 Access 数据库并尝试编辑链接表信息时，我可以打开表并查看我的数据。但是，当我关闭 Access 并重新打开 Access 数据库时，密码信息似乎已恢复，并且出现 ODBC 连接错误。

有人知道我做错了什么吗？

作为后续，我们似乎有十几个 Access 数据库，其中包含大量链接表，都需要此更新。这是更新此信息的最佳方式吗？链接表似乎是使用不同的机器创建的，因为 ODBC 连接中指定的 Workstation-ID 不同。

Answer 1

编写一个例程，从 TableDef 更新 Connect 属性并使用 RefreshLink 保存更改。

Answer 2

链接表管理器 (LTM) 的问题在于，链接表实际上是指向 SQL 视图的链接。在这种情况下，LTM 将重新链接“表”而不为它们重新分配正确的 PK，并且它们将变得不可更新。 我写了一些我以前从 VBE 开始的代码，这是一件快速而肮脏的事情，但如果你需要它，你肯定可以适应它。 有 2 个 subs，一个用于表，一个用于 passthru 查询。

Option Compare Database
option explicit

Const kOld = "remote.g"  'string to identify old server
'new server odbc string
Const kConnLux = "ODBC;DRIVER=SQL Server Native Client 10.0;SERVER=xxxx;UID=yyyy;PWD=zzzz;"

Sub UpdateTables()
    Dim db As Database, td As TableDef
    Dim hasIndex As Boolean, strSql As String

    Set db = CurrentDb
    For Each td In db.TableDefs
        If InStr(1, td.Connect, kOld) > 0 Then  'lien vers CE serveur ?
            If td.Name Like "dbo_vw*" And td.Indexes.count = 1 Then 'table = vue attachee --> pbl de clef primaire
                strSql = "CREATE INDEX " & td.Indexes(0).Name & " ON [" & td.Name & "](" & td.Indexes(0).Fields & ")"
                ' convert field list from (+fld1;+fld2) to (fld1,fld2)
                strSql = Replace(strSql, "+", "")
                strSql = Replace(strSql, ";", ",")
                hasIndex = True
            Else
                hasIndex = False
            End If
            td.Connect = kConnLux
            td.RefreshLink
            Debug.Print td.Name
            If hasIndex And td.Indexes.count = 0 Then
                ' if index now removed then re-create it
                CurrentDb.Execute strSql
            End If
        End If
    Next td
    Debug.Print "Done"
End Sub

Sub UpdateQueries()
    Dim db As Database
    Dim td As QueryDef
    Set db = CurrentDb
    For Each td In db.QueryDefs
        If InStr(1, td.Connect, kOld) > 0 Then
            td.Connect = kConnLux
            Debug.Print td.Name, td.Connect
        End If
    Next td
End Sub