Perl 哈希值的基本原理

Question

我决定尝试 Perl，我偶然发现了一种似乎有效的语言结构，但我简直不敢相信它是有效的。我想这背后有一些理由，所以我决定问一个问题。

获取以下 Perl 代码：

%data = ('John Paul' => ('Age' => 45), 'Lisa' => 30);
print "\$data{'John Paul'} = $data{'John Paul'}{'Age'}\n";
print "\$data{'Lisa'} = $data{'Lisa'}\n";

我的目的是检查哈希的哈希是如何工作的。上面的代码打印：

$data{'John Paul'} =
$data{'Lisa'} =

要使其成为一个有效的哈希散列，需要：

%data = ('John Paul' => {'Age' => 45}, 'Lisa' => 30);

结果是：

$data{'John Paul'} = 45
$data{'Lisa'} = 30

有谁知道：

1. 为什么不统一，内部哈希需要{}而不是()？
2. 当内部散列使用() 而不是{} 时，为什么我没有收到错误或警告？很容易犯这样的错误。更重要的是，('Age' => 45) 不仅破坏了 'John Paul' 的值，还破坏了 'Lisa' 的值。我无法想象在数千行代码的项目中寻找这种“错误”。

Answer 1

( 'John Paul' => ( 'Age' => 45 ), 'Lisa' => 30 )

只是另一种写作方式

'John Paul', 'Age', 45, 'Lisa', 30

Parens 不会创建任何数据结构；它们只会影响(3+4)*5 中的优先级。我们不写的原因

my %h = a => 4;

或同等的

my %h = 'a', 4;

是不是会被解释为

( my %h = 'a' ), 4;

创建哈希的是my %data，而不是括号。赋值的右侧只是在堆栈上放置任意数量的标量，而不是散列。赋值运算符将这些标量添加到哈希中。

---

但有时，我们想创建一个匿名哈希。这就是{} 的用武之地。

my %data = ( 'John Paul' => { 'Age' => 45 }, 'Lisa' => 30 );

基本上等价于

my %anon = ( 'Age' => 45 );
my %data = ( 'John Paul' => \%anon, 'Lisa' => 30 );

请注意，\%anon 返回标量，即对哈希的引用。这与( 'John Paul' => \%anon, 'Lisa' => 30 ) 和'John Paul' => \%anon, 'Lisa' => 30 返回的四个 标量有着根本的不同。

---

为什么不统一，内部哈希需要{}而不是()？

这个问题的一个基本前提是错误的：哈希不需要()。例如，以下是完全有效的：

my %h1 = 'm'..'p';

sub f { return x => 4, y => 5 }
my %h2 = f();

my %h3 = do { i => 6, j => 7 };

() 与哈希无关。缺乏统一性源于缺乏平行性。一个使用{} 创建一个哈希。使用() 覆盖优先级。

由于括号只会影响优先级，因此可以使用

my %data = ( 'John Paul' => ({ 'Age' => 45 }), 'Lisa' => 30 );  # ok (but weird)

这与以下内容大不相同：

my %data = ( 'John Paul' => ( 'Age' => 45 ), 'Lisa' => 30 );  # XXX

当内部哈希使用 () 而不是 {} 时，为什么我没有收到错误或警告？

不仅使用() 有效，通常还需要在包含逗号的表达式周围使用()。那么它究竟应该在什么时候发出警告呢？关键是这是否应该是警告还是perlcritic 发现的东西是有争议的，至少乍一看是这样。后者肯定会找到这个，但我不知道它是否存在规则。

Answer 2

为什么不统一，内部哈希需要{}而不是()？

对哈希的赋值是一个标量列表（在键和值之间交替）。

您不能将哈希值（因为它不是标量）作为值，但您可以有哈希引用。

列表被展平。

当内部哈希使用 () 而不是 {} 时，为什么我没有收到错误或警告？

因为您没有使用 the use strict; use warnings; pragmas 将它们打开（默认情况下由于可怕的向后兼容性而关闭，但它将是 on by default in Perl 7）。