将输入框默认更改为当前输入

Question

我正在尝试编写一个宏，它会将输入框默认值重新设置为最后输入的值，所以如果我在下面的输入框中键入“2”，默认值将更改为 2，下次宏已运行。

只有在我运行宏的工作簿关闭后，才能恢复原来的默认值

（Excel 2007）

    ROWSDOWN = InputBox("enter no.of rows DOWN to move the cells", "VerticalMove", _
            -1) 'default -1 (=1 row up)

我已尝试设置PREV_ROWSDOWN = ROWSDOWN，但我的尝试（如下）不起作用：下次我运行宏时，输入框默认值为 0。宏结束时 PREV_ROWSDOWN（和 ROWSDOWN）的值会丢失吗？

ROWSDOWN = InputBox("enter no.of rows DOWN to move the cells (0=no change, - =move UP)", "VerticalMove", _
            PREV_ROWSDOWN) 'should set default as value entered last time the macro run
        PREV_ROWSDOWN = ROWSDOWN ''NW-not saved after macro finished, default changed to "0"

我怎样才能做到这一点？

Answer 1

1. 为了更好的可读性，我建议不要使用全大写变量名。
2. 我建议使用Application.InputBox method 而不仅仅是InputBox，因为您可以在那里指定输入的Type。因此，如果您设置Type:=1，则用户只能输入数字。
3. 确保使用Option Explicit 来强制进行正确的变量声明。我建议始终激活 Option Explicit：在 VBA 编辑器中转到 Tools › Options › Require Variable Declaration。

一直持续到工作簿关闭……

要使您的默认值在工作簿关闭之前保持不变，您需要将其声明为Static（请参阅Static statement）。

Option Explicit

Public Sub Test()
    Static RowsDown As Long  'Static variables will keep the value until next call
    RowsDown = Application.InputBox(Prompt:="enter no.of rows DOWN to move the cells (0=no change, - =move UP)", Title:="VerticalMove", Default:=RowsDown, Type:=1) 
End Sub

请注意，如果您关闭并重新打开工作簿，它将再次以 0 开始。如果您希望它有所不同，您需要在您的 Static 行之后添加类似以下内容：

If RowsDown = 0 Then RowsDown = -1

---

永远坚持……

当工作簿关闭时，变量无法保留值。如果即使工作簿关闭并重新打开，您也想让您的价值保持不变，那么您需要将其保存到（可能是隐藏的）工作表的单元格中。

Option Explicit

Public Sub Test()
    Dim RowsDown As Long
    RowsDown = Application.InputBox(Prompt:="enter no.of rows DOWN to move the cells (0=no change, - =move UP)", Title:="VerticalMove", Default:=ThisWorkbook.Worksheets("hiddensheet").Range("A1").Value, Type:=1) 
    ThisWorkbook.Worksheets("hiddensheet").Range("A1").Value = RowsDown
End Sub

Answer 2

需要定义全局变量，这里用输入框定义宏，如：

Private lastInput

Sub DefaultForInputBox()
    lastInput = InputBox("Enter some value", "InputBox", lastInput)
End Sub