Delphi - 在 OSX 上获取完整的堆栈跟踪

Question

我有一个可以记录堆栈跟踪的应用程序，以后可以用于调试。

在 Windows 上，我使用了 JEDI 项目提供的出色的 JCLDebug 单元。

现在我的应用程序在 OSX 上运行，我遇到了一些麻烦 - 我不知道在发生异常时如何获取正确的堆栈跟踪。

我已经掌握了基础知识 -

1) 我可以使用“backtrace”（在 libSystem.dylib 中找到）获取堆栈跟踪

2) 可以使用 Delphi 的链接器提供的 .map 文件将生成的回溯转换为行号

我剩下的问题是 - 我不知道从哪里调用回溯。我知道 Delphi 使用 Mach 异常（在单独的线程上），并且我不能使用 posix 信号，但这就是我设法解决的所有问题。

我可以在“try...except”块中获得回溯，但不幸的是，到那时堆栈已经结束了。

如何安装一个合适的异常记录器，它会在异常发生后立即运行？

更新：

根据“Honza R”的建议，我查看了“GetExceptionStackInfoProc”程序。

这个函数确实让我“了解”异常处理过程，但不幸的是，我遇到了一些以前遇到的相同问题。

首先 - 在桌面平台上，这个函数“GetExceptionStackInfoProc”只是一个函数指针，您可以使用您自己的异常信息处理程序分配它。所以开箱即用，Delphi 不提供任何堆栈信息提供程序。

如果我将一个函数分配给“GetExceptionStackInfoProc”，然后在其中运行“回溯”，我会收到一个堆栈跟踪，但该跟踪是相对于异常处理程序，而不是导致异常的线程。

“GetExceptionStackInfoProc”确实包含指向“TExceptionRecord”的指针，但可用的文档非常有限。

我可能超出了我的深度，但是如何从正确的线程获取堆栈跟踪？我是否可以将自己的“回溯”函数注入异常处理程序，然后从那里返回到标准异常处理程序？

更新 2

更多细节。需要澄清的一件事 - 这个问题是关于由 MACH 消息处理的异常，而不是完全在 RTL 内处理的软件异常。

Embarcadero 已经布置了一些 cmets 以及这些功能 -

    System.Internal.MachExceptions.pas -> catch_exception_raise_state_identity

    {
     Now we set up the thread state for the faulting thread so that when we
     return, control will be passed to the exception dispatcher on that thread,
     and this POSIX thread will continue watching for Mach exception messages.
     See the documentation at <code>DispatchMachException()</code> for more
     detail on the parameters loaded in EAX, EDX, and ECX.
    }

    System.Internal.ExcUtils.pas -> SignalConverter

    {
      Here's the tricky part.  We arrived here directly by virtue of our
      signal handler tweaking the execution context with our address.  That
      means there's no return address on the stack.  The unwinder needs to
      have a return address so that it can unwind past this function when
      we raise the Delphi exception.  We will use the faulting instruction
      pointer as a fake return address.  Because of the fencepost conditions
      in the Delphi unwinder, we need to have an address that is strictly
      greater than the actual faulting instruction, so we increment that
      address by one.  This may be in the middle of an instruction, but we
      don't care, because we will never be returning to that address.
      Finally, the way that we get this address onto the stack is important.
      The compiler will generate unwind information for SignalConverter that
      will attempt to undo any stack modifications that are made by this
      function when unwinding past it.  In this particular case, we don't want
      that to happen, so we use some assembly language tricks to get around
      the compiler noticing the stack modification.
    }

这似乎是我遇到的问题的原因。

当我在这个异常系统将控制权交给 RTL 之后执行堆栈跟踪时，它看起来像这样 - （请记住，堆栈展开器已被回溯例程取代。回溯会将控制权交给展开器完成后）

0: MyExceptionBacktracer
1: initunwinder in System.pas
2: RaiseSignalException in System.Internal.ExcUtils.pas 

由于RaiseSignalException 被SignalConverter 调用，我被引导相信libc 提供的backtrace 函数与对堆栈所做的修改不兼容。因此，它无法读取超出该点的堆栈，但堆栈仍然存在于下方。

有谁知道该怎么做（或者我的假设是否正确）？

更新 3

我终于设法在 OSX 上获得了正确的堆栈跟踪。非常感谢 Honza 和 Sebastian。通过结合他们的两种技术，我发现了一些可行的方法。

对于其他可以从中受益的人，这里是基本来源。请记住，我不太确定它是否 100% 正确，如果您可以提出改进建议，请继续。这种技术在 Delphi 解开故障线程上的堆栈之前挂钩到异常，并补偿可能事先发生的任何堆栈帧损坏。

unit MyExceptionHandler;

interface

implementation

uses
  SysUtils;

var
  PrevRaiseException: function(Exc: Pointer): LongBool; cdecl;

function backtrace2(base : NativeUInt; buffer : PPointer; size : Integer) : Integer;
var SPMin   : NativeUInt;
begin
  SPMin:=base;
  Result:=0;
  while (size > 0) and (base >= SPMin) and (base <> 0) do begin

    buffer^:=PPointer(base + 4)^;
    base:=PNativeInt(base)^;

    //uncomment to test stacktrace
    //WriteLn(inttohex(NativeUInt(buffer^), 8));

    Inc(Result);
    Inc(buffer);
    Dec(size);

  end;
  if (size > 0) then buffer^:=nil;
end;

procedure UnInstallExceptionHandler; forward;

var
  InRaiseException: Boolean;

function RaiseException(Exc: Pointer): LongBool; cdecl;
var b : NativeUInt;
    c : Integer;
    buff : array[0..7] of Pointer;
begin
  InRaiseException := True;

  asm
    mov b, ebp
  end;

  c:=backtrace2(b - $4 {this is the compiler dependent value}, @buff, Length(buff));
  //... do whatever you want to do with the stacktrace

  Result := PrevRaiseException(Exc);
  InRaiseException := False;
end;

procedure InstallExceptionHandler;
var
  U: TUnwinder;
begin
  GetUnwinder(U);
  Assert(Assigned(U.RaiseException));
  PrevRaiseException := U.RaiseException;
  U.RaiseException := RaiseException;
  SetUnwinder(U);
end;

procedure UnInstallExceptionHandler;
var
  U: TUnwinder;
begin
  GetUnwinder(U);
  U.RaiseException := PrevRaiseException;
  SetUnwinder(U);
end;

initialization
  InstallExceptionHandler;
end.

Answer 1

您可以在Exception 类中使用GetExceptionStackInfoProc、CleanUpStackInfoProc 和GetStackInfoStringProc，您需要将堆栈跟踪保存在GetExceptionStackInfoProc 中，然后使用GetStackInfoStringProc 检索它，如果您使用@，它将被RTL 调用Exception 的 987654328@ 属性。也许您还可以查看https://bitbucket.org/shadow_cs/delphi-arm-backtrace，它在 Android 上演示了这一点。

要在 Mac OS X 上正确执行此操作，不能使用 libc backtrace 函数，因为 Delphi 在从 Exception.RaisingException 调用 GetExceptionStackInfoProc 时会损坏堆栈帧。必须使用自己的实现，该实现能够从不同的基地址遍历堆栈，可以手动更正。

然后您的GetExceptionStackInfoProc 将如下所示（我在此示例中使用 XE5，添加到 EBP 波纹管的值可能会根据您使用的编译器而有所不同，并且此示例仅在 Mac OS X 上进行了测试，Windows 实现可能会也可能不会不同）：

var b : NativeUInt;
    c : Integer;
    buff : array[0..7] of Pointer;
begin
  asm
    mov b, ebp
  end;
  c:=backtrace2(b - $14 {this is the compiler dependent value}, @buff, Length(buff));
  //... do whatever you want to do with the stacktrace
end;

backtrace2 函数看起来像这样（请注意，在实现中缺少停止条件和其他验证，以确保在堆栈遍历期间不会导致 AV）：

function backtrace2(base : NativeUInt; buffer : PPointer; size : Integer) : Integer;
var SPMin   : NativeUInt;
begin
  SPMin:=base;
  Result:=0;
  while (size > 0) and (base >= SPMin) and (base <> 0) do begin
    buffer^:=PPointer(base + 4)^;
    base:=PNativeInt(base)^;
    Inc(Result);

    Inc(buffer);
    Dec(size);
  end;
  if (size > 0) then buffer^:=nil;
end;

Answer 2

您可以将自己连接到异常展开器。然后你可以在异常发生的地方调用回溯。这是一个例子。 SBMapFiles 单元是我用来读取地图文件的。不需要获取异常调用堆栈。

unit MyExceptionHandler;

interface

implementation

uses
  Posix.Base, SysUtils, SBMapFiles;

function backtrace(result: PNativeUInt; size: Integer): Integer; cdecl; external libc name '_backtrace';
function _NSGetExecutablePath(buf: PAnsiChar; BufSize: PCardinal): Integer; cdecl; external libc name '__NSGetExecutablePath';

var
  PrevRaiseException: function(Exc: Pointer): LongBool; cdecl;
  MapFile: TSBMapFile;

const
  MaxDepth = 20;
  SkipFrames = 3;

procedure ShowCurrentStack;
var
  StackLog: PNativeUInt; //array[0..10] of Pointer;
  Cnt: Integer;
  I: Integer;
begin
  {$POINTERMATH ON}
  GetMem(StackLog, SizeOf(Pointer) * MaxDepth);
  try
    Cnt := backtrace(StackLog, MaxDepth);

    for I := SkipFrames to Cnt - 1 do
    begin
      if StackLog[I] = $BE00EF00 then
      begin
        WriteLn('---');
        Break;
      end;
      WriteLn(IntToHex(StackLog[I], 8), ' ', MapFile.GetFunctionName(StackLog[I]));
    end;

   finally
    FreeMem(StackLog);
   end;
  {$POINTERMATH OFF}
end;

procedure InstallExceptionHandler; forward;
procedure UnInstallExceptionHandler; forward;

var
  InRaiseException: Boolean;

function RaiseException(Exc: Pointer): LongBool; cdecl;
begin
  InRaiseException := True;
  ShowCurrentStack;

  Result := PrevRaiseException(Exc);
  InRaiseException := False;
end;

procedure InstallExceptionHandler;
var
  U: TUnwinder;
begin
  GetUnwinder(U);
  Assert(Assigned(U.RaiseException));
  PrevRaiseException := U.RaiseException;
  U.RaiseException := RaiseException;
  SetUnwinder(U);
end;

procedure UnInstallExceptionHandler;
var
  U: TUnwinder;
begin
  GetUnwinder(U);
  U.RaiseException := PrevRaiseException;
  SetUnwinder(U);
end;

procedure LoadMapFile;
var
  FileName: array[0..255] of AnsiChar;
  Len: Integer;
begin
  if MapFile = nil then
  begin
    MapFile := TSBMapFile.Create;
    Len := Length(FileName);
    _NSGetExecutablePath(@FileName[0], @Len);
    if FileExists(ChangeFileExt(FileName, '.map')) then
      MapFile.LoadFromFile(ChangeFileExt(FileName, '.map'));
  end;
end;

initialization
  LoadMapFile;
  InstallExceptionHandler;
end.